[kde-base] KDE SC 4.7.2

Package-Manager: portage-2.2.0_alpha61/cvs/Linux x86_64

2 files changed, 75 insertions, 1 deletions

diff --git a/kde-base/kdepimlibs/ChangeLog b/kde-base/kdepimlibs/ChangeLog
index 99bb2f183adb..b7c89b635d01 100644
--- a/kde-base/kdepimlibs/ChangeLog
+++ b/kde-base/kdepimlibs/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kdepimlibs
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.111 2011/09/07 20:13:48 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.112 2011/10/06 18:10:54 alexxy Exp $
+
+*kdepimlibs-4.7.2 (06 Oct 2011)
+
+  06 Oct 2011; Alexey Shvetsov <alexxy@gentoo.org> +kdepimlibs-4.7.2.ebuild:
+  Version bump KDE SC 4.7.2
 
 *kdepimlibs-4.7.1 (07 Sep 2011)
 
diff --git a/kde-base/kdepimlibs/kdepimlibs-4.7.2.ebuild b/kde-base/kdepimlibs/kdepimlibs-4.7.2.ebuild
new file mode 100644
index 000000000000..9bf0f3dd6b89
--- /dev/null
+++ b/kde-base/kdepimlibs/kdepimlibs-4.7.2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/kdepimlibs-4.7.2.ebuild,v 1.1 2011/10/06 18:10:54 alexxy Exp $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+CPPUNIT_REQUIRED="optional"
+KDE_SCM="git"
+inherit kde4-base
+
+DESCRIPTION="Common library for KDE PIM apps."
+HOMEPAGE="http://www.kde.org/"
+
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+LICENSE="LGPL-2.1"
+IUSE="debug ldap semantic-desktop"
+
+# some akonadi tests timeout, that probaly needs more work as its ~700 tests
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=app-crypt/gpgme-1.1.6
+	dev-libs/libgpg-error
+	>=dev-libs/libical-0.43
+	dev-libs/cyrus-sasl
+	$(add_kdebase_dep kdelibs 'semantic-desktop=')
+	semantic-desktop? (
+		>=app-office/akonadi-server-1.5.80
+		media-libs/phonon
+		x11-misc/shared-mime-info
+	)
+	ldap? ( net-nds/openldap )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.35.0-r5
+"
+RDEPEND="${COMMON_DEPEND}"
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	# Disable hardcoded checks
+	sed -r -e '/find_package\((Akonadi|SharedDesktopOntologies|Soprano|Nepomuk)/{/macro_optional_/!s/find/macro_optional_&/}' \
+		-e '/macro_log_feature\((Akonadi|SHAREDDESKTOPONTOLOGIES|Soprano|Nepomuk)_FOUND/s/ TRUE / FALSE /' \
+		-e '/add_subdirectory\((akonadi|mailtransport)/{/macro_optional_/!s/add/macro_optional_&/}' \
+		-i CMakeLists.txt || die
+	if ! use semantic-desktop; then
+		sed -e '/include(SopranoAddOntology)/s/^/#DISABLED /' \
+			-i CMakeLists.txt || die
+		# More reliable than -DBUILD_akonadi=OFF
+		rm -r akonadi mailtransport || die
+	fi
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build handbook doc)
+		$(cmake-utils_use_with ldap)
+		$(cmake-utils_use_with semantic-desktop Akonadi)
+		$(cmake-utils_use_with semantic-desktop SharedDesktopOntologies)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		# $(cmake-utils_use_with prison)
+		-DWITH_Prison=NO
+	)
+
+	kde4-base_src_configure
+}