Version bump.

Package-Manager: portage-2.2.0_alpha120/cvs/Linux x86_64

4 files changed, 155 insertions, 2 deletions

diff --git a/media-libs/libmediainfo/ChangeLog b/media-libs/libmediainfo/ChangeLog
index 70d3eb8a956c..03702eceeded 100644
--- a/media-libs/libmediainfo/ChangeLog
+++ b/media-libs/libmediainfo/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libmediainfo
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.55 2012/08/04 19:56:28 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.56 2012/08/09 09:38:57 radhermit Exp $
+
+*libmediainfo-0.7.59 (09 Aug 2012)
+
+  09 Aug 2012; Tim Harder <radhermit@gentoo.org> +libmediainfo-0.7.59.ebuild:
+  Version bump.
 
   04 Aug 2012; Tim Harder <radhermit@gentoo.org>
   -files/libmediainfo-0.7.54-system-tinyxml.patch, -libmediainfo-0.7.56.ebuild:
diff --git a/media-libs/libmediainfo/libmediainfo-0.7.59.ebuild b/media-libs/libmediainfo/libmediainfo-0.7.59.ebuild
new file mode 100644
index 000000000000..4d45599883fb
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-0.7.59.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.59.ebuild,v 1.1 2012/08/09 09:38:57 radhermit Exp $
+
+EAPI="4"
+
+inherit autotools eutils flag-o-matic multilib
+
+MY_PN="MediaInfo"
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="http://mediainfo.sourceforge.net/"
+SRC_URI="mirror://sourceforge/mediainfo/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl doc mms static-libs"
+
+RDEPEND="sys-libs/zlib
+	dev-libs/tinyxml2
+	>=media-libs/libzen-0.4.28[static-libs=]
+	curl? ( net-misc/curl )
+	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+S=${WORKDIR}/${MY_PN}Lib/Project/GNU/Library
+
+src_prepare() {
+	# Don't force -O2 by default
+	sed -i -e "s:-O2::" configure.ac
+
+	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		--with-libtinyxml2 \
+		$(use_with curl libcurl) \
+		$(use_with mms libmms) \
+		$(use_enable static-libs static) \
+		$(use_enable static-libs staticlibs)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		cd "${WORKDIR}/${MY_PN}Lib/Source/Doc"
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	default
+
+	edos2unix ${PN}.pc #414545
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	insinto /usr/include/${MY_PN}DLL
+	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+	if use doc; then
+		dohtml -r "${WORKDIR}"/${MY_PN}Lib/Doc/*
+	fi
+
+	prune_libtool_files
+}
diff --git a/media-libs/libzen/ChangeLog b/media-libs/libzen/ChangeLog
index d88ba6607068..85b4827e4cba 100644
--- a/media-libs/libzen/ChangeLog
+++ b/media-libs/libzen/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libzen
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libzen/ChangeLog,v 1.48 2012/08/04 19:57:23 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libzen/ChangeLog,v 1.49 2012/08/09 09:34:16 radhermit Exp $
+
+*libzen-0.4.28 (09 Aug 2012)
+
+  09 Aug 2012; Tim Harder <radhermit@gentoo.org> +libzen-0.4.28.ebuild:
+  Version bump.
 
   04 Aug 2012; Tim Harder <radhermit@gentoo.org>
   -files/libzen-0.4.21-no-tinyxml.patch, -libzen-0.4.26.ebuild:
diff --git a/media-libs/libzen/libzen-0.4.28.ebuild b/media-libs/libzen/libzen-0.4.28.ebuild
new file mode 100644
index 000000000000..f79b7a986948
--- /dev/null
+++ b/media-libs/libzen/libzen-0.4.28.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libzen/libzen-0.4.28.ebuild,v 1.1 2012/08/09 09:34:16 radhermit Exp $
+
+EAPI="4"
+
+inherit autotools multilib eutils
+
+MY_PN="ZenLib"
+DESCRIPTION="Shared library for libmediainfo and mediainfo"
+HOMEPAGE="http://sourceforge.net/projects/zenlib"
+SRC_URI="mirror://sourceforge/zenlib/${MY_PN}%20-%20Sources/${PV}/${PN}_${PV}.tar.bz2"
+
+LICENSE="as-is ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc static-libs"
+
+DEPEND="virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+S=${WORKDIR}/${MY_PN}/Project/GNU/Library
+
+src_prepare() {
+	sed -i -e "s:-O2::" configure.ac
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-unicode \
+		--enable-shared \
+		$(use_enable static-libs static)
+}
+
+src_compile() {
+	default
+
+	if use doc ; then
+		cd "${WORKDIR}"/${MY_PN}/Source/Doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	default
+
+	# remove since the pkgconfig file should be used instead
+	rm "${D}"/usr/bin/libzen-config
+
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Format/Html Format/Http HTTP_Client ; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}/Source/${MY_PN}/${x}/*.h
+	done
+
+	dodoc "${WORKDIR}"/${MY_PN}/History.txt
+	if use doc ; then
+		dohtml "${WORKDIR}"/${MY_PN}/Doc/*
+	fi
+
+	prune_libtool_files
+}