Version bump based on Nokilis work on bug 471554, drop old.

Package-Manager: portage-2.2.0_alpha177/cvs/Linux x86_64
Manifest-Sign-Key: 0x62EEF090

1 files changed, 70 insertions, 0 deletions

diff --git a/media-sound/flacon/flacon-0.8.0.ebuild b/media-sound/flacon/flacon-0.8.0.ebuild
new file mode 100644
index 000000000000..9313aaf08b1e
--- /dev/null
+++ b/media-sound/flacon/flacon-0.8.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/flacon/flacon-0.8.0.ebuild,v 1.1 2013/05/29 08:33:51 xmw Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+PLOCALES="cs_CZ es_MX fr gl it pl_PL pt_BR ro_RO ru si_LK uk zh_CN zh_TW"
+
+inherit python-single-r1 l10n
+
+DESCRIPTION="Extracts audio tracks from audio CD image to separate tracks"
+HOMEPAGE="https://code.google.com/p/flacon/"
+SRC_URI="https://flacon.googlecode.com/files/${P}.tgz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flac mac mp3 mp4 ogg replaygain tta wavpack"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/PyQt4[X,${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	media-sound/shntool[mac?]
+	flac? ( media-libs/flac )
+	mac? ( media-sound/mac )
+	mp3? ( media-sound/lame )
+	mp4? ( media-libs/faac )
+	ogg? ( media-sound/vorbis-tools )
+	tta? ( media-sound/ttaenc )
+	wavpack? ( media-sound/wavpack )
+	replaygain? (
+		mp3? ( media-sound/mp3gain )
+		ogg? ( media-sound/vorbisgain )
+	)"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	my_rm_loc() {
+		rm -v "translations/${PN}_${1}."{ts,qm} || die
+	}
+
+	l10n_find_plocales_changes "translations" "${PN}_" '.qm'
+	l10n_for_each_disabled_locale_do my_rm_loc
+	touch translations/dummy.{ts,qm}
+
+	python_fix_shebang .
+
+	sed -e '/cd $(INST_DIR) && python -mcompileall ./d' -i Makefile || die
+
+	# do not use /tmp/ for tests
+	sed -e "s,/tmp/,${T}/," \
+		-i Makefile tests/flacon_tests.py || die
+}
+
+src_compile() { :; }
+
+src_test() {
+	"${PYTHON}" tests/flacon_tests.py --verbose || die "Testing failed with ${PYTHON}"
+}
+
+src_install() {
+	default
+
+	rm "${D}"/usr/share/${PN}/translations/dummy.qm
+
+	python_optimize "${D}"
+}