Version bump.

Package-Manager: portage-2.2.0_alpha41/cvs/Linux x86_64

4 files changed, 148 insertions, 2 deletions

diff --git a/net-nds/ypbind/ChangeLog b/net-nds/ypbind/ChangeLog
index b90a7646e262..00437710d867 100644
--- a/net-nds/ypbind/ChangeLog
+++ b/net-nds/ypbind/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-nds/ypbind
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nds/ypbind/ChangeLog,v 1.67 2011/05/20 19:17:57 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nds/ypbind/ChangeLog,v 1.68 2011/06/17 03:12:18 jer Exp $
+
+*ypbind-1.33 (17 Jun 2011)
+
+  17 Jun 2011; Jeroen Roovers <jer@gentoo.org> +ypbind-1.33.ebuild:
+  Version bump.
 
   20 May 2011; Kacper Kowalik <xarthisius@gentoo.org> -ypbind-1.31.ebuild:
   Drop old
diff --git a/net-nds/ypbind/ypbind-1.33.ebuild b/net-nds/ypbind/ypbind-1.33.ebuild
new file mode 100644
index 000000000000..b19922348cca
--- /dev/null
+++ b/net-nds/ypbind/ypbind-1.33.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-nds/ypbind/ypbind-1.33.ebuild,v 1.1 2011/06/17 03:12:18 jer Exp $
+
+EAPI="2"
+
+inherit eutils
+
+MY_P=${PN}-mt-${PV}
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="Multithreaded NIS bind service (ypbind-mt)"
+HOMEPAGE="http://www.linux-nis.org/nis/ypbind-mt/index.html"
+SRC_URI="ftp://ftp.kernel.org/pub/linux/utils/net/NIS/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug dbus nls slp"
+
+RDEPEND="
+	net-nds/yp-tools
+	debug? ( dev-libs/dmalloc )
+	dbus? ( dev-libs/dbus-glib )
+	slp? ( net-libs/openslp )
+	|| ( net-nds/portmap net-nds/rpcbind )"
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-1.31-man-port.patch" # bug #77810
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) $(use_enable slp) \
+		$(use_with debug dmalloc) $(use_enable dbus dbus-nm)
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+
+	dodoc AUTHORS ChangeLog README THANKS TODO
+
+	insinto /etc
+	newins etc/yp.conf yp.conf.example
+
+	newconfd "${FILESDIR}/ypbind.confd-r1" ypbind
+	newinitd "${FILESDIR}/ypbind.initd" ypbind
+}
+
+pkg_postinst() {
+	einfo "To complete setup, you will need to edit /etc/conf.d/ypbind."
+	einfo "If you are using dhcpcd, be sure to add the -Y option to"
+	einfo "dhcpcd_eth0 (or eth1, etc.) to keep dhcpcd from clobbering"
+	einfo "/etc/yp.conf."
+}
diff --git a/net-nds/ypserv/ChangeLog b/net-nds/ypserv/ChangeLog
index c13844512a6c..a44058fc4503 100644
--- a/net-nds/ypserv/ChangeLog
+++ b/net-nds/ypserv/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-nds/ypserv
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nds/ypserv/ChangeLog,v 1.52 2011/05/28 17:49:02 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nds/ypserv/ChangeLog,v 1.53 2011/06/17 03:11:57 jer Exp $
+
+*ypserv-2.25 (17 Jun 2011)
+
+  17 Jun 2011; Jeroen Roovers <jer@gentoo.org> +ypserv-2.25.ebuild:
+  Version bump.
 
   28 May 2011; Raúl Porcel <armin76@gentoo.org> ypserv-2.22.ebuild,
   ypserv-2.23.ebuild, ypserv-2.24.ebuild:
diff --git a/net-nds/ypserv/ypserv-2.25.ebuild b/net-nds/ypserv/ypserv-2.25.ebuild
new file mode 100644
index 000000000000..bce619e60e3e
--- /dev/null
+++ b/net-nds/ypserv/ypserv-2.25.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-nds/ypserv/ypserv-2.25.ebuild,v 1.1 2011/06/17 03:11:57 jer Exp $
+
+EAPI="2"
+
+inherit autotools
+
+DESCRIPTION="Network Information Service server"
+HOMEPAGE="http://www.linux-nis.org/nis/"
+SRC_URI="mirror://kernel/linux/utils/net/NIS/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="slp"
+
+DEPEND=">=sys-libs/gdbm-1.8.0
+	 slp? ( net-libs/openslp )"
+RDEPEND="${DEPEND}
+	 || ( net-nds/rpcbind net-nds/portmap )"
+
+src_prepare() {
+	# The configure script does not provide a command-line flag to control usage
+	# of slp. Use a brutal method in case we need to disable it.
+	if ! use slp; then
+		sed -i -e 's/USE_SLP=1/USE_SLP=0/g' configure.in
+		eautoreconf
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS README THANKS TODO
+
+	insinto /etc
+	doins etc/ypserv.conf etc/netgroup etc/netmasks
+	insinto /var/yp
+	newins etc/securenets securenets.default
+
+	newconfd "${FILESDIR}/ypserv.confd" ypserv
+	newconfd "${FILESDIR}/rpc.yppasswdd.confd" rpc.yppasswdd
+	newconfd "${FILESDIR}/rpc.ypxfrd.confd" rpc.ypxfrd
+
+	newinitd "${FILESDIR}/ypserv" ypserv
+	newinitd "${FILESDIR}/rpc.yppasswdd-r1" rpc.yppasswdd
+	newinitd "${FILESDIR}/rpc.ypxfrd-2.23" rpc.ypxfrd
+
+	echo "CONFIG_PROTECT=\"/var/yp/Makefile\"" > "${T}"/10ypserv
+	doenvd "${T}"/10ypserv
+}
+
+pkg_preinst() {
+	# This ebuilds installs an env file which CONFIG_PROTECTs /var/yp/Makefile,
+	# but if the user is migrating from older ypserv, this won't take effect
+	# immediately. Keep the older setup with Makefile.dist file and ask the user
+	# to migrate.
+	if [ -f "${ROOT}/var/yp/Makefile.dist" ]; then
+		mv "${D}/var/yp/Makefile" "${D}/var/yp/Makefile.dist" \
+			|| die "mv failed"
+		cp "${ROOT}/var/yp/Makefile" "${D}/var/yp/Makefile" \
+			|| die "cp failed"
+		elog "Please remove ${ROOT}/var/yp/Makefile.dist after making sure that"
+		elog "${ROOT}/var/yp/Makefile looks fine to you. It is now"
+		elog "CONFIG_PROTECTed, so further changes should be managed with"
+		elog "usual config management tools like etc-update or dispatch-conf."
+	fi
+}
+
+pkg_postinst() {
+	einfo "To complete setup, you will need to edit /var/yp/securenets,"
+	einfo "/etc/conf.d/ypserv, /etc/ypserv.conf, /etc/conf.d/rpc.yppasswdd"
+	einfo "and possibly /var/yp/Makefile."
+
+	einfo "To start the services at boot, you need to enable ypserv and optionally"
+	einfo "the rpc.yppasswdd and/or rpc.ypxfrd services"
+}