Version bump to development release.

Package-Manager: portage-2.2.0_alpha100/cvs/Linux x86_64

2 files changed, 61 insertions, 1 deletions

diff --git a/xfce-base/xfconf/ChangeLog b/xfce-base/xfconf/ChangeLog
index f56e82a19c85..46168671d0f0 100644
--- a/xfce-base/xfconf/ChangeLog
+++ b/xfce-base/xfconf/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for xfce-base/xfconf
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfconf/ChangeLog,v 1.59 2012/04/07 18:23:01 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfconf/ChangeLog,v 1.60 2012/04/14 08:38:26 ssuominen Exp $
+
+*xfconf-4.9.1 (14 Apr 2012)
+
+  14 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> +xfconf-4.9.1.ebuild:
+  Version bump to development release.
 
   07 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> xfconf-4.9.0.ebuild:
   Raise some dependencies according to upstream git.
diff --git a/xfce-base/xfconf/xfconf-4.9.1.ebuild b/xfce-base/xfconf/xfconf-4.9.1.ebuild
new file mode 100644
index 000000000000..94c51967a0fa
--- /dev/null
+++ b/xfce-base/xfconf/xfconf-4.9.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfconf/xfconf-4.9.1.ebuild,v 1.1 2012/04/14 08:38:26 ssuominen Exp $
+
+EAPI=4
+inherit xfconf
+
+DESCRIPTION="A simple client-server configuration storage and query system for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~x64-solaris"
+IUSE="debug perl"
+
+RDEPEND=">=dev-libs/dbus-glib-0.98
+	>=dev-libs/glib-2.24
+	>=xfce-base/libxfce4util-4.9
+	perl? ( dev-perl/glib-perl )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	sys-devel/gettext
+	perl? (
+		dev-perl/extutils-depends
+		dev-perl/extutils-pkgconfig
+		)"
+
+pkg_setup() {
+	XFCONF=(
+		$(use_enable perl perl-bindings)
+		$(xfconf_use_debug)
+		$(use_enable debug checks)
+		--with-perl-options=INSTALLDIRS=vendor
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	[[ ${CHOST} == *-darwin* ]] && XFCONF+=( --disable-visibility ) #366857
+
+	DOCS=( AUTHORS ChangeLog NEWS TODO )
+}
+
+src_compile() {
+	emake OTHERLDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	xfconf_src_install
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+}