1 files changed, 54 insertions, 0 deletions
diff --git a/dev-java/stringtemplate/stringtemplate-3.2.ebuild b/dev-java/stringtemplate/stringtemplate-3.2.ebuild
new file mode 100644
index 000000000000..617d155117be
--- /dev/null
+++ b/dev-java/stringtemplate/stringtemplate-3.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/stringtemplate/stringtemplate-3.2.ebuild,v 1.1 2009/03/29 00:13:43 betelgeuse Exp $
+
+EAPI="2"
+JAVA_PKG_IUSE="doc source"
+WANT_ANT_TASKS="ant-antlr"
+
+inherit eutils java-pkg-2 java-ant-2
+
+MY_PV="${PV/_beta/b}"
+S_PV="${PV/_beta/.b}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="A Java template engine"
+HOMEPAGE="http://www.stringtemplate.org/"
+SRC_URI="http://www.stringtemplate.org/download/${MY_P}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~x86"
+IUSE=""
+
+# no junit targets in build.xml, but unconditional compile and jar of test
+# classes, oh well
+COMMON_DEPEND="dev-java/antlr:0
+	dev-java/junit:0"
+
+RDEPEND=">=virtual/jre-1.4
+	${COMMON_DEPEND}"
+
+DEPEND=">=virtual/jdk-1.4
+	${COMMON_DEPEND}"
+
+S="${WORKDIR}/${PN}-${S_PV}"
+
+java_prepare() {
+	# fix <javadoc> call
+	epatch "${FILESDIR}/${PN}-3.1_beta1-javadoc.patch"
+	java-ant_rewrite-classpath
+	rm -v lib/*.jar || die
+	# force regeneration with our antlr2
+	touch src/org/antlr/stringtemplate/language/*.g || die
+}
+
+EANT_GENTOO_CLASSPATH="antlr,junit"
+EANT_DOC_TARGET="javadocs"
+
+src_install() {
+	java-pkg_dojar build/${PN}.jar
+
+	dodoc README.txt CHANGES.txt || die
+	use doc && java-pkg_dojavadoc docs/api
+	use source && java-pkg_dosrc src/org
+}