1 files changed, 48 insertions, 0 deletions
diff --git a/dev-python/scimath/scimath-4.1.0.ebuild b/dev-python/scimath/scimath-4.1.0.ebuild
new file mode 100644
index 000000000000..4b3e651d2fa3
--- /dev/null
+++ b/dev-python/scimath/scimath-4.1.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/scimath/scimath-4.1.0.ebuild,v 1.1 2012/10/09 12:42:44 patrick Exp $
+
+EAPI=4
+
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="3.* *-jython 2.7-pypy-*"
+DISTUTILS_SRC_TEST="nosetests"
+
+inherit distutils virtualx
+
+DESCRIPTION="Enthought Tool Suite: Scientific and mathematical tools"
+HOMEPAGE="http://code.enthought.com/projects/sci_math/ http://pypi.python.org/pypi/scimath"
+SRC_URI="http://www.enthought.com/repo/ets/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/traits-4.1
+	>=dev-python/traitsui-4.1
+	sci-libs/scipy"
+DEPEND="dev-python/setuptools
+	doc? ( dev-python/sphinx )
+	test? (
+		${RDEPEND}
+		media-fonts/font-cursor-misc
+		media-fonts/font-misc-misc
+		x11-apps/xhost
+	)"
+
+src_compile() {
+	distutils_src_compile
+	use doc && emake -C docs html
+}
+
+src_test() {
+	VIRTUALX_COMMAND="distutils_src_test" virtualmake
+}
+
+src_install() {
+	find -name "*LICENSE*.txt" -delete
+	distutils_src_install
+
+	use doc && dohtml -r docs/build/html/*
+}