1 files changed, 39 insertions, 0 deletions
diff --git a/sys-power/powernowd/powernowd-1.00-r2.ebuild b/sys-power/powernowd/powernowd-1.00-r2.ebuild
new file mode 100644
index 000000000000..6e6064119588
--- /dev/null
+++ b/sys-power/powernowd/powernowd-1.00-r2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-power/powernowd/powernowd-1.00-r2.ebuild,v 1.1 2013/08/31 15:32:00 pacho Exp $
+
+EAPI=5
+inherit linux-info systemd toolchain-funcs
+
+DESCRIPTION="Daemon to control the speed and voltage of CPUs"
+HOMEPAGE="http://www.deater.net/john/powernowd.html"
+SRC_URI="http://www.deater.net/john/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+pkg_setup() {
+	CONFIG_CHECK="~CPU_FREQ"
+	WARNING_CPU_FREQ="Powernowd needs CPU_FREQ turned on!"
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	rm -f Makefile
+	tc-export CC
+}
+
+src_compile() {
+	emake powernowd
+}
+
+src_install() {
+	dosbin powernowd
+	dodoc README
+
+	newconfd "${FILESDIR}"/powernowd.confd powernowd
+	newinitd "${FILESDIR}"/powernowd.initd powernowd
+	systemd_dounit "${FILESDIR}"/${PN}.service
+}