app-misc/tomboy/tomboy-1.2.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/tomboy/tomboy-1.2.1.ebuild,v 1.7 2010/12/08 20:13:36 pacho Exp $

EAPI=2

inherit eutils gnome2 mono

DESCRIPTION="Desktop note-taking application"
HOMEPAGE="http://www.beatniksoftware.com/tomboy/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc x86"
IUSE="eds galago"

RDEPEND=">=dev-lang/mono-2
	>=dev-dotnet/gtk-sharp-2.12.6-r1
	>=dev-dotnet/gconf-sharp-2.24.0
	>=dev-dotnet/gnome-sharp-2.24.0
	>=dev-dotnet/gnome-panel-sharp-2.24.0
	>=dev-dotnet/gnome-desktop-sharp-2.24.0
	>=dev-dotnet/dbus-sharp-0.4
	>=dev-dotnet/dbus-glib-sharp-0.3
	>=dev-dotnet/mono-addins-0.3
	>=x11-libs/gtk+-2.12.0
	>=dev-libs/atk-1.2.4
	>=gnome-base/gconf-2
	>=app-text/gtkspell-2.0.9
	|| ( gnome-base/gnome-panel[bonobo] <gnome-base/gnome-panel-2.32 )
	eds? ( dev-libs/gmime:2.4[mono] )
	galago? ( =dev-dotnet/galago-sharp-0.5* )"
DEPEND="${RDEPEND}
	app-text/gnome-doc-utils
	app-text/rarian
	dev-libs/libxml2[python]
	sys-devel/gettext
	dev-util/pkgconfig
	>=dev-util/intltool-0.35"

DOCS="AUTHORS ChangeLog INSTALL NEWS README"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-update-mimedb"
}

src_prepare() {
	gnome2_src_prepare

	sed -i -e '/DISABLE_DEPRECATED/d' $(find . -name 'Makefile.in') || die

	# Fix intltoolize broken file, see upstream #577133
	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
		|| die "sed failed"

	# Fix xmllint validation, bug #330693
	epatch "${FILESDIR}/${P}-xmllint-validation.patch"
}

src_configure() {
	gnome2_src_configure $(use_enable galago) $(use_enable eds evolution)
}