dev-games/neotools/neotools-0.8.2-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-games/neotools/neotools-0.8.2-r1.ebuild,v 1.3 2010/10/15 12:34:29 ranger Exp $

EAPI=2
inherit eutils autotools

DESCRIPTION="Various development tools for NeoEngine"
HOMEPAGE="http://www.neoengine.org/"
SRC_URI="mirror://sourceforge/neoengine/neotools-${PV}.tar.bz2"

LICENSE="MPL-1.1"
SLOT="0"
KEYWORDS="ppc x86"
IUSE=""

DEPEND=">=dev-games/neoengine-${PV}
	app-arch/bzip2"

S=${WORKDIR}/neotools

src_prepare() {
	sed -i \
		-e 's/BUILD_STATIC/BUILD_DYNAMIC/g' \
		-e 's/_static//g' \
		nscemake/Makefile.am \
		|| die "sed failed"
	sed -i \
		-e 's:"bzip2/bzlib.h":<bzlib.h>:' \
		npacmake/main.cpp \
		|| die "sed failed"
	sed -i \
		-e '/npacmake_SOURCES/s/main.cpp.*/main.cpp/' \
		-e '/npacmake_LDADD/s/$/ -lbz2/' \
		npacmake/Makefile.am \
		|| die "sed failed"
	sed -i \
		-e 's/ -Werror//' \
		configure.in \
		|| die "sed failed"

	epatch "${FILESDIR}"/${P}-errno.patch \
		"${FILESDIR}"/${P}-gcc43.patch

	eautoreconf
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog*
}