games-arcade/jardinains/jardinains-2.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/jardinains/jardinains-2.0-r1.ebuild,v 1.4 2015/02/19 10:41:07 ago Exp $

EAPI=5
inherit eutils games

DESCRIPTION="Arkanoid with Gnomes"
HOMEPAGE="http://www.jardinains2.com"
SRC_URI="mirror://gentoo/JN2_1_FREE_LIN.tar.gz"

LICENSE="jardinains"
SLOT="0"
KEYWORDS="-* amd64 ~x86"
IUSE=""
RESTRICT="strip"
QA_EXECSTACK="${GAMES_PREFIX_OPT:1}/jardinains/jardinains"

DEPEND=""
RDEPEND="sys-libs/libstdc++-v3:5
	amd64? ( sys-libs/libstdc++-v3:5[multilib] )
	|| (
		(
			>=virtual/opengl-7.0-r1[abi_x86_32(-)]
			>=virtual/glu-9.0-r1[abi_x86_32(-)]
			>=x11-libs/libX11-1.6.2[abi_x86_32(-)]
			>=x11-libs/libXxf86vm-1.1.3[abi_x86_32(-)]
		)
		amd64? (
			>=app-emulation/emul-linux-x86-xlibs-1.0-r1[-abi_x86_32(-)]
			app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)]
		)
	)"

dir=${GAMES_PREFIX_OPT}/${PN}
QA_PREBUILT="${dir:1}/${PN}"

src_unpack() {
	unpack JN2_1_FREE_LIN.tar.gz
	cd "${WORKDIR}"
	mv "Jardinains 2!" ${P}
}

src_prepare() {
	# clean Mac fork files (bug #295782)
	find . -type f -name "._*" -exec rm -f '{}' +
	epatch "${FILESDIR}"/strings-pt.patch
}

src_install() {
	exeinto "${dir}"
	doexe jardinains || die
	insinto "${dir}"
	doins -r LICENSE.txt data help || die "doins failed"

	games_make_wrapper jardinains ./jardinains "${dir}" "${dir}"

	make_desktop_entry jardinains "Jardinains 2"
	touch "${D}${dir}/data/prefs.xml"
	prepgamesdirs
	chmod g+rw "${D}${dir}/data/prefs.xml"
	chmod -R g+rw "${D}${dir}/data/players"
}

pkg_postinst() {
	games_pkg_postinst
	elog "Due to the way this software is designed all user preferences for"
	elog "graphics, audio and other in game data are shared among all users"
	elog "of the computer. For that reason some files in the instalation   "
	elog "folder are writable by any user in the games group."
}