net-analyzer/nb/nb-0.8.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nb/nb-0.8.3.ebuild,v 1.6 2011/11/28 07:07:06 radhermit Exp $

EAPI="3"

inherit autotools eutils

DESCRIPTION="Nodebrain is a tool to monitor and do event correlation."
HOMEPAGE="http://nodebrain.sourceforge.net/"
SRC_URI="mirror://sourceforge/nodebrain/nodebrain-${PV}.tar.gz"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE="static-libs"

DEPEND="
	dev-lang/perl
	dev-util/pkgconfig
	sys-apps/texinfo
"
RDEPEND="
	!sys-boot/netboot
	!www-apps/nanoblogger
"

S="${WORKDIR}/nodebrain-${PV}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-configure.patch

	# fdl.texi is not included in the sources
	sed -i doc/nbTutorial/nbTutorial.texi -e '/@include fdl.texi/d' || die

	eautoreconf
}

src_configure() {
	econf $(use_enable static-libs static) --include=/usr/include
}

src_compile() {
	# Fails at parallel make
	emake -j1 || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	use static-libs || find "${D}" -name '*.la' -delete
	dodoc AUTHORS NEWS README THANKS sample/*
	dohtml html/*
}