net-dialup/xc/xc-4.3.2-r4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dialup/xc/xc-4.3.2-r4.ebuild,v 1.1 2014/04/19 01:43:08 kumba Exp $

EAPI=5

inherit eutils flag-o-matic multilib toolchain-funcs

DESCRIPTION="Modem dialout & serial terminal program"
HOMEPAGE="http://www.ibiblio.org/pub/Linux/apps/serialcomm/dialout/"
SRC_URI="http://www.ibiblio.org/pub/Linux/apps/serialcomm/dialout/${P}.tar.gz"

LICENSE="xc-radley"
SLOT="0"
KEYWORDS="~amd64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE=""

RDEPEND="sys-libs/ncurses"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	epatch "${FILESDIR}"/${P}-implicit-decl.patch
	epatch "${FILESDIR}"/${P}-add-115200.patch
	epatch "${FILESDIR}"/${P}-fix-set_bps-overflow.patch

	sed -i \
		-e "/^libdir/s:/lib/:/$(get_libdir)/:" \
		-e "/strip/d" \
		Makefile || die
	# bug 459796
	append-libs "$($(tc-getPKG_CONFIG) --libs ncurses)"
}

src_compile() {
	tc-export AR CC RANLIB
	emake WARN="" all
}

src_install() {
	default
	insinto /usr/$(get_libdir)/xc
	doins phonelist xc.init dotfiles/.[a-z]*
}