blob: 028bf283658ec415e3a8c4c573de01d2454d5af4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/netifrc/netifrc-0.2.4.ebuild,v 1.1 2014/07/16 19:21:58 robbat2 Exp $
EAPI=5
inherit eutils udev
DESCRIPTION="Gentoo Network Interface Management Scripts"
HOMEPAGE="http://www.gentoo.org/proj/en/base/openrc/"
if [[ ${PV} == "9999" ]]; then
EGIT_REPO_URI="git://git.overlays.gentoo.org/proj/${PN}.git"
inherit git-2
else
SRC_URI="http://dev.gentoo.org/~robbat2/distfiles/${P}.tar.bz2"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
fi
LICENSE="BSD-2"
SLOT="0"
IUSE=""
COMMON_DEPEND="!<sys-fs/udev-init-scripts-26-r1"
DEPEND="${COMMON_DEPEND}
kernel_linux? ( virtual/pkgconfig )"
RDEPEND="${COMMON_DEPEND}
>=sys-apps/openrc-0.12
!<sys-apps/openrc-0.12"
src_prepare() {
if [[ ${PV} == "9999" ]] ; then
local ver="git-${EGIT_VERSION:0:6}"
sed -i "/^GITVER[[:space:]]*=/s:=.*:=${ver}:" mk/git.mk || die
einfo "Producing ChangeLog from Git history"
GIT_DIR="${S}/.git" git log >"${S}"/ChangeLog
fi
# Allow user patches to be applied without modifying the ebuild
epatch_user
}
src_compile() {
MAKE_ARGS="${MAKE_ARGS}
LIBEXECDIR=${EPREFIX}/lib/${PN} PF=${PF}
UDEVDIR=$(get_udevdir)"
use prefix && MAKE_ARGS="${MAKE_ARGS} MKPREFIX=yes PREFIX=${EPREFIX}"
emake ${MAKE_ARGS} all
}
src_install() {
emake ${MAKE_ARGS} DESTDIR="${D}" install
dodoc README CREDITS FEATURE-REMOVAL-SCHEDULE STYLE TODO ChangeLog
}
pkg_postinst() {
if [[ ! -e "${EROOT}"/etc/conf.d/net && -z $REPLACING_VERSIONS ]]; then
elog "The network configuration scripts will use dhcp by"
elog "default to set up your interfaces."
elog "If you need to set up something more complete, see"
elog "${EROOT}/usr/share/doc/${P}/README"
fi
}
|
GitWeb
