blob: 6f2f31634c38cfa69d509a7eb622cc6586e91885 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/openntpd/openntpd-20080406-r7.ebuild,v 1.11 2014/04/06 14:50:23 vapier Exp $
EAPI=5
inherit autotools eutils toolchain-funcs systemd user
MY_P="${P/-/_}p"
DEB_VER="6"
DESCRIPTION="Lightweight NTP server ported from OpenBSD"
HOMEPAGE="http://www.openntpd.org/"
SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${MY_P}.orig.tar.gz
mirror://debian/pool/main/${PN:0:1}/${PN}/${MY_P}-${DEB_VER}.debian.tar.gz"
LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~x86-fbsd"
IUSE="ssl selinux"
RDEPEND="ssl? ( dev-libs/openssl )
selinux? ( sec-policy/selinux-ntp )
!<=net-misc/ntp-4.2.0-r2
!net-misc/ntp[-openntpd]"
DEPEND="${RDEPEND}
virtual/yacc"
S="${WORKDIR}/${MY_P/_/-}"
pkg_setup() {
export NTP_HOME="${NTP_HOME:=/var/lib/openntpd/chroot}"
enewgroup ntp
enewuser ntp -1 -1 "${NTP_HOME}" ntp
# make sure user has correct HOME as flipng between
# the standard ntp pkg and this one was possible in
# the past
if [[ $(egethome ntp) != ${NTP_HOME} ]]; then
ewarn "From this version on, the homedir of the ntp user cannot be changed"
ewarn "dynamically after the installation. For homedir different from"
ewarn "/var/lib/openntpd/chroot set NTP_HOME in your make.conf and re-emerge."
esethome ntp "${NTP_HOME}"
fi
}
src_prepare() {
sed -i '/NTPD_USER/s:_ntp:ntp:' ntpd.h || die
epatch "${WORKDIR}"/debian/patches/*.patch
epatch "${FILESDIR}/${P}-pidfile.patch"
epatch "${FILESDIR}/${P}-signal.patch"
epatch "${FILESDIR}/${P}-dns-timeout.patch"
sed -i 's:debian:gentoo:g' ntpd.conf || die
eautoreconf # deb patchset touches .ac files and such
}
src_configure() {
econf \
--disable-strip \
$(use_with !ssl builtin-arc4random) \
AR="$(type -p $(tc-getAR))"
}
src_install() {
default
newinitd "${FILESDIR}/${PN}.init.d-${PV}-r6" ntpd
newconfd "${FILESDIR}/${PN}.conf.d-${PV}-r6" ntpd
systemd_newunit "${FILESDIR}/${PN}.service-${PV}-r3" ntpd.service
}
pkg_config() {
einfo "Setting up chroot for ntp in ${NTP_HOME}"
# remove localtime file from previous installations
rm -f "${EROOT}${NTP_HOME}"etc/localtime
mkdir -p "${EROOT}${NTP_HOME}"etc
if ! ln "${EROOT}"etc/localtime "${EROOT}${NTP_HOME}"etc/localtime ; then
cp "${EROOT}"etc/localtime "${EROOT}${NTP_HOME}"etc/localtime || die
einfo "We could not create a hardlink from /etc/localtime to ${NTP_HOME}etc/localtime,"
einfo "so please run 'emerge --config =${CATEGORY}/${PF}' whenever you changed"
einfo "your timezone."
fi
chown -R root:root "${EROOT}${NTP_HOME}" || die
}
pkg_postinst() {
pkg_config
[[ -f ${EROOT}var/log/ntpd.log ]] && \
ewarn "There is an orphaned logfile '${EROOT}var/log/ntpd.log', please remove it!"
}
pkg_postrm() {
# remove localtime file from previous installations
rm -f "${EROOT}${NTP_HOME}"etc/localtime
}
|
GitWeb