blob: 669bdb09f9f19dccbac12468d41bb80fe4d03768 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/glusterfs/glusterfs-3.1.0.ebuild,v 1.1 2010/10/14 17:09:17 xarthisius Exp $
EAPI="2"
inherit autotools elisp-common eutils multilib versionator
DESCRIPTION="GlusterFS is a powerful network/cluster filesystem"
HOMEPAGE="http://www.gluster.org/"
SRC_URI="http://ftp.gluster.com/pub/gluster/${PN}/$(get_version_component_range '1-2')/${PV}/${P}.tar.gz"
LICENSE="AGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="emacs +fuse infiniband static-libs vim-syntax extras"
DEPEND="emacs? ( virtual/emacs )
fuse? ( >=sys-fs/fuse-2.7.0 )
infiniband? ( sys-infiniband/libibverbs )"
RDEPEND="${DEPEND}"
SITEFILE="50${PN}-mode-gentoo.el"
src_prepare() {
epatch "${FILESDIR}/${P}-parallel-build.patch" \
"${FILESDIR}/${PN}-2.0.8-docdir.patch"
eautoreconf
}
src_configure() {
econf \
$(use_enable fuse fuse-client) \
$(use_enable infiniband ibverbs) \
$(use_enable static-libs static) \
--disable-bdb \
--docdir=/usr/share/doc/${PF} \
--localstatedir=/var
}
src_compile() {
emake || die
if use emacs ; then
elisp-compile extras/glusterfs-mode.el || die
fi
}
src_install() {
emake DESTDIR="${D}" install || die
if use emacs ; then
elisp-install ${PN} extras/glusterfs-mode.el* || die
elisp-site-file-install "${FILESDIR}/${SITEFILE}"
fi
if use vim-syntax ; then
insinto /usr/share/vim/vimfiles/ftdetect; doins "${FILESDIR}/glusterfs.vim" || die
insinto /usr/share/vim/vimfiles/syntax; doins extras/glusterfs.vim || die
fi
if use extras ; then
newbin extras/volgen/glusterfs-volgen glusterfs-volgen || die
newbin extras/backend-xattr-sanitize.sh glusterfs-backend-xattr-sanitize || die
newbin extras/migrate-unify-to-distribute.sh glusterfs-migrate-unify-to-distribute || die
fi
dodoc AUTHORS ChangeLog NEWS README THANKS || die
newinitd "${FILESDIR}/${PN}.initd" glusterfsd || die
newconfd "${FILESDIR}/${PN}.confd" glusterfsd || die
keepdir /var/log/${PN} || die
}
pkg_postinst() {
elog "The glusterfs startup script can be multiplexed."
elog "The default startup script uses /etc/conf.d/glusterfs to configure the"
elog "separate service. To create additional instances of the glusterfs service"
elog "simply create a symlink to the glusterfs startup script."
elog
elog "Example:"
elog " # ln -s glusterfsd /etc/init.d/glusterfsd2"
elog " # ${EDITOR} /etc/glusterfs/glusterfsd2.vol"
elog "You can now treat glusterfsd2 like any other service"
echo
elog "You can mount exported GlusterFS filesystems through /etc/fstab instead of"
elog "through a startup script instance. For more information visit:"
elog "http://www.gluster.org/docs/index.php/Mounting_a_GlusterFS_Volume"
echo
elog "If you are upgrading from glusterfs 3.0.x please read:"
elog "http://www.gluster.com/community/documentation/index.php/Gluster_3.0_to_3.1_Upgrade_Guide"
echo
ewarn "You need to use a ntp client to keep the clocks synchronized across all"
ewarn "of your servers. Setup a NTP synchronizing service before attempting to"
ewarn "run GlusterFS."
use emacs && elisp-site-regen
}
pkg_postrm() {
use emacs && elisp-site-regen
}
|
GitWeb