x11-misc/trayer/trayer-1.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/trayer/trayer-1.0-r1.ebuild,v 1.11 2012/07/29 17:50:44 armin76 Exp $

EAPI=4
inherit toolchain-funcs

DESCRIPTION="Lightweight GTK+ based systray for UNIX desktop"
HOMEPAGE="http://home.gna.org/fvwm-crystal/"
SRC_URI="http://download.gna.org/fvwm-crystal/trayer/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc ppc64 x86"
IUSE=""
RDEPEND="
	dev-libs/glib:2
	x11-libs/gdk-pixbuf
	x11-libs/gtk+:2
	x11-libs/libX11
"
DEPEND="
	${RDEPEND}
	virtual/pkgconfig
"

src_prepare() {
	# fix for as-needed, bug #141707
	# fix pre-stripped files, bug #252098
	sed -i Makefile \
		-e 's:$(LIBS) $(OBJ) $(SYSTRAYOBJ):$(OBJ) $(SYSTRAYOBJ) $(LIBS):' \
		-e 's:strip:true:g' \
		|| die
	# fix underlinking, bug #369591
	sed -i Makefile.common \
		-e '/^LIBS/s:).*: x11):' \
		-e '/^INC/s:).*: x11):' \
		|| die
}

src_compile() {
	emake -j1 CC=$(tc-getCC) CFLAGS="${CFLAGS}"
}

src_install() {
	dobin trayer
	doman trayer.1
	dodoc CHANGELOG CREDITS README
}