sys-fs/sanoid: add 9999

Signed-off-by: John M. Harris Jr. <johnmh@johnmh.me>

2 files changed, 71 insertions, 0 deletions

diff --git a/sys-fs/sanoid/metadata.xml b/sys-fs/sanoid/metadata.xml
new file mode 100644
index 000000000..a99815b2a
--- /dev/null
+++ b/sys-fs/sanoid/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>johnmh@johnmh.me</email>
+    <name>John M. Harris, Jr.</name>
+  </maintainer>
+  <upstream>
+    <changelog>https://github.com/jimsalterjrs/sanoid/releases</changelog>
+    <bugs-to>https://github.com/jimsalterjrs/sanoid/issues</bugs-to>
+    <remote-id type="github">jimsalterjrs/sanoid</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/sys-fs/sanoid/sanoid-9999.ebuild b/sys-fs/sanoid/sanoid-9999.ebuild
new file mode 100644
index 000000000..3a8a47483
--- /dev/null
+++ b/sys-fs/sanoid/sanoid-9999.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Policy-driven snapshot management and replication tools for OpenZFS."
+HOMEPAGE="https://github.com/jimsalterjrs/sanoid"
+
+if [[ "${PV}" = *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/jimsalterjrs/${PN^}.git"
+else
+	SRC_URI="https://github.com/jimsalterjrs/${PN^}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+IUSE="gzip lzop pigz zstd"
+BDEPEND="
+	dev-lang/perl
+	sys-apps/groff
+"
+RDEPEND="
+	dev-lang/perl
+	dev-perl/Capture-Tiny
+	dev-perl/Config-IniFiles
+	sys-apps/pv
+	sys-block/mbuffer
+	sys-fs/zfs
+	virtual/perl-Data-Dumper
+	virtual/perl-Getopt-Long
+	virtual/ssh
+	gzip?    ( app-arch/gzip )
+	lzop?    ( app-arch/lzop )
+	pigz?    ( app-arch/pigz )
+	zstd?    ( app-arch/zstd )
+"
+
+src_compile() {
+	perldoc -onroff -dsanoid.1 sanoid || die "Failed to compile sanoid.1"
+	perldoc -onroff -dsyncoid.1 syncoid || die "Failed to compile syncoid.1"
+}
+
+src_install() {
+	dobin sanoid
+	dobin syncoid
+
+	doman sanoid.1 syncoid.1
+
+	insinto /etc/sanoid
+	doins "sanoid.defaults.conf"
+
+	elog "You will need to set up your /etc/sanoid/sanoid.conf file before"
+	elog "running sanoid for the first time. For details, please consult the"
+	elog "documentation on https://github.com/jimsalterjrs/sanoid."
+}