dev-python/poetry-core: initial commit, add 1.0.7

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
Signed-off-by: Michał Górny <mgorny@gentoo.org>

3 files changed, 68 insertions, 0 deletions

diff --git a/dev-python/poetry-core/Manifest b/dev-python/poetry-core/Manifest
new file mode 100644
index 000000000000..4c3631d4a43d
--- /dev/null
+++ b/dev-python/poetry-core/Manifest
@@ -0,0 +1 @@
+DIST poetry-core-1.0.7.gh.tar.gz 414539 BLAKE2B 570f13e3c7298fd822a38b75c49c623bde4fa780b3787c3c9cfa3939bb68fee3eeaf6190013117a6e751cb6f87a15b343ba183529fcc07d30e37988097954d4a SHA512 40a8b17ae7c51135eb5f96ec76426f075075de7dafff8ab828fe3b47d13759856a7fd2e7504c1216c4f942befde2c6d42c3976978202ce7aa224e966162bd8e5
diff --git a/dev-python/poetry-core/metadata.xml b/dev-python/poetry-core/metadata.xml
new file mode 100644
index 000000000000..fe238cb762d0
--- /dev/null
+++ b/dev-python/poetry-core/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">poetry-core</remote-id>
+		<remote-id type="github">python-poetry/poetry-core</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/poetry-core/poetry-core-1.0.7.ebuild b/dev-python/poetry-core/poetry-core-1.0.7.ebuild
new file mode 100644
index 000000000000..720027adf43f
--- /dev/null
+++ b/dev-python/poetry-core/poetry-core-1.0.7.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Poetry PEP 517 Build Backend"
+HOMEPAGE="https://pypi.org/project/poetry-core/ https://github.com/python-poetry/poetry-core"
+SRC_URI="
+	https://github.com/python-poetry/poetry-core/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# check inside src/poetry/core/_vendor/vendor.txt
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lark-parser[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pyparsing[${PYTHON_USEDEP}]
+	dev-python/pyrsistent[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pep517[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Those "fail" bacause of glob file path resulting from newer versions
+	# in our tree than vendored. But those don't affect anything.
+	tests/masonry/builders/test_sdist.py::test_default_with_excluded_data
+	tests/masonry/builders/test_wheel.py::test_default_src_with_excluded_data
+)
+
+src_prepare() {
+	# remove vendoring of dependencies
+	rm -r poetry/core/_vendor || die
+	sed -e '/__vendor_site__/d' -i poetry/core/__init__.py || die
+
+	distutils-r1_src_prepare
+}