dev-dotnet/dotnet-sdk-bin: bump to 8.0.203

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

2 files changed, 163 insertions, 0 deletions

diff --git a/dev-dotnet/dotnet-sdk-bin/Manifest b/dev-dotnet/dotnet-sdk-bin/Manifest
index ea3ec5bc5d6c..8be9b19d2c24 100644
--- a/dev-dotnet/dotnet-sdk-bin/Manifest
+++ b/dev-dotnet/dotnet-sdk-bin/Manifest
@@ -28,3 +28,9 @@ DIST dotnet-sdk-8.0.202-linux-musl-arm.tar.gz 221670792 BLAKE2B 9652853fc212cebb
 DIST dotnet-sdk-8.0.202-linux-musl-arm64.tar.gz 221390383 BLAKE2B 5102262974b802c3a0dfefec58d025612c0fbe5f120bb57ba7a482b966193d2ff1ef762e70a14a3a38014dd35b394010e76148710e99599d2ce5fa36ca22f786 SHA512 f5d1f025d18062247e7c392903c012b5e7f625609cff19d9eac81755065fc468a1d66b0396492258257bf42a88a07e40a040d0cb296bed620d326f58e2cd69cd
 DIST dotnet-sdk-8.0.202-linux-musl-x64.tar.gz 226257142 BLAKE2B dff4d5e9b97dd3af8646bf280efb097ff0dcf1f9df77e56c8ee5b3d35e78fe6ac655d8c609ef593339bac6dfbe585fd67525a19ec321ee63a75127edb72da913 SHA512 809d8e488723e7be053cf572222b0d81ea7dd10a5034617f044bd0c752f6eaa14034c2d13f093a06d64af6b5b5cc65efb5d9fbb9de8edd00d215cc8e9f26a587
 DIST dotnet-sdk-8.0.202-linux-x64.tar.gz 226275111 BLAKE2B 17ffb1919ecde439b48db6c8df52a58b12dbd3e077bde6da1f9c7057b162e35cca0e4ce4eef9cdc8c929209773dce236d31e8ca8abcf780255e577a045db144d SHA512 e0e790c7cc6f8129913317d326c599ff8e8ed4927d4e0adccbe55c50be5c353fe3d83043e529973ced2b302b8432c2ab31533b94ffe9c363eaa9964a7160643a
+DIST dotnet-sdk-8.0.203-linux-arm.tar.gz 221422071 BLAKE2B c4cb0184eb5bb4435c2f73058f857dba1d163c81d23ad33645b82ea4afa9981c09c70be7a054596ed77cf653967d07a1f95deea9ff1dc3d7986c35e264eb86e9 SHA512 ebebd4f3be6e9772f23d313b991950d6997716fc0f9c079414a72a0f998c55a32ea19f145ea1b1724fea527ca12a7cbea7afefa60a520679a20b99f68f184e15
+DIST dotnet-sdk-8.0.203-linux-arm64.tar.gz 221512731 BLAKE2B d23b64c4263a674c79a649c1afe2d301f81598150d2bed61c8c8abf6175b46ef5b10b10307e1c85247d1724689c3608f7712cbbf90b2b4f5bb0afa9fc55d9e35 SHA512 cda16b2141c1115ec42303d82f2720ddf5368b7242207e21d3fdd81fa89df2676f0d394ca7293c76c35ed2448b289174739771ec447404ad9c84c72459cc0d81
+DIST dotnet-sdk-8.0.203-linux-musl-arm.tar.gz 221707667 BLAKE2B f4561a35e0ce7481fbe29b2b5148d2f598690b26faf7b252efab6fc1f660553042b4e159aee1060687f6024158a9fd9582aef2c563a840f9a5ff44473186d0ad SHA512 4ae716cac29a5381dc6341b2e5214f57c7b82928a0a756a2b3cef7d8063d52a29a66cea10e3ae03e379ec220a833e479f944dc762b3cc44c255a02bb715b84a5
+DIST dotnet-sdk-8.0.203-linux-musl-arm64.tar.gz 221570139 BLAKE2B b6d9aaafc0cdab6c83db9d466c54ea6e5be5be612494d7a34ab41138a7354925b5960b3a79b74271ead757f9a2d1c95e89869b81128c6d3deff7c64630ffecfd SHA512 33cf09807d9280d3f4a860ea7650f73732c7d86d462a06b6e40e7945d0fc8c6e9c5e799059de86939cd0de88d35afb67d1829150b9fc2e5ccdce0d55d9e771f7
+DIST dotnet-sdk-8.0.203-linux-musl-x64.tar.gz 226138600 BLAKE2B 5df8fedafdfae99eb86944e1f0684f907a1e5e4405d5c45367ff6e50f0f9006035367603c15db56492b23e175a82f400efdff1c6ba5ae199a6062f5b3eb6890a SHA512 d2b6d8b411470c1a856d546dea087285dad7adb3b3fc5335b024d6f9054ac869073742c283158294c7b866dbd58dda4d9fa2a2c245fb4618c44ca5a61ddec7da
+DIST dotnet-sdk-8.0.203-linux-x64.tar.gz 226131531 BLAKE2B 6b70ea6b4c462cb489e87837e7d98166a41d6e7eefc93534318d4d4504c1e441cc7aad3bc19da05758049f771c3423d5d20786691cfbc179a090ed1ae3847693 SHA512 78b1913b54a1a4c9f13cc2864a11540b5fd3bdf4ebb49837483e19c0906a1890f2dfcf173635a1c89714bf735cbcaa01db0f7ae90add5295da69a0638ed5e60e
diff --git a/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-8.0.203.ebuild b/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-8.0.203.ebuild
new file mode 100644
index 000000000000..35d59a50075c
--- /dev/null
+++ b/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-8.0.203.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+SDK_SLOT="$(ver_cut 1-2)"
+RUNTIME_SLOT="${SDK_SLOT}.3"
+
+DESCRIPTION=".NET is a free, cross-platform, open-source developer platform"
+HOMEPAGE="https://dotnet.microsoft.com/
+	https://github.com/dotnet/dotnet/"
+SRC_URI="
+amd64? (
+	elibc_glibc? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-x64.tar.gz )
+	elibc_musl? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-x64.tar.gz )
+)
+arm? (
+	elibc_glibc? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm.tar.gz )
+	elibc_musl? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm.tar.gz )
+)
+arm64? (
+	elibc_glibc? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm64.tar.gz )
+	elibc_musl? ( https://dotnetcli.azureedge.net/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm64.tar.gz )
+)
+"
+S="${WORKDIR}"
+
+LICENSE="MIT"
+SLOT="${SDK_SLOT}/${RUNTIME_SLOT}"
+KEYWORDS="~amd64 ~arm ~arm64"
+
+# STRIP="llvm-strip" corrupts some executables when using the patchelf hack,
+# bug https://bugs.gentoo.org/923430
+RESTRICT="splitdebug strip"
+
+CURRENT_NUGETS_DEPEND="
+	~dev-dotnet/dotnet-runtime-nugets-${RUNTIME_SLOT}
+"
+EXTRA_NUGETS_DEPEND="
+	~dev-dotnet/dotnet-runtime-nugets-6.0.28
+	~dev-dotnet/dotnet-runtime-nugets-7.0.17
+"
+NUGETS_DEPEND="
+	${CURRENT_NUGETS_DEPEND}
+	${EXTRA_NUGETS_DEPEND}
+"
+
+RDEPEND="
+	app-crypt/mit-krb5:0/0
+	dev-libs/icu
+	dev-util/lttng-ust:0/2.12
+	sys-libs/zlib:0/1
+"
+BDEPEND="
+	dev-util/patchelf
+"
+IDEPEND="
+	app-eselect/eselect-dotnet
+"
+PDEPEND="
+	${NUGETS_DEPEND}
+"
+
+QA_PREBUILT="*"
+
+MUSL_BAD_LINKS=(
+	apphost
+	createdump
+	dotnet
+	libSystem.Globalization.Native.so
+	libSystem.IO.Compression.Native.so
+	libSystem.Native.so
+	libSystem.Net.Security.Native.so
+	libSystem.Security.Cryptography.Native.OpenSsl.so
+	libclrgc.so
+	libclrjit.so
+	libcoreclr.so
+	libcoreclrtraceptprovider.so
+	libdbgshim.so
+	libhostfxr.so
+	libhostpolicy.so
+	libmscordaccore.so
+	libmscordbi.so
+	libnethost.so
+	singlefilehost
+)
+MUSL_BAD_SONAMES=(
+	libc.musl-aarch64.so.1
+	libc.musl-armv7.so.1
+	libc.musl-x86_64.so.1
+)
+
+src_prepare() {
+	default
+
+	# Fix musl libc SONAME links, bug https://bugs.gentoo.org/894760
+	if use elibc_musl ; then
+		local musl_bad_link
+		local musl_bad_link_path
+		local musl_bad_soname
+
+		for musl_bad_link in "${MUSL_BAD_LINKS[@]}" ; do
+			while read -r musl_bad_link_path ; do
+				# Skip if file either does not end with ".so" or is not executable.
+				# Using "case" here for easier matching in case we have to add
+				# a special exception.
+				case "${musl_bad_link_path}" in
+					*.so )
+						:
+						;;
+					* )
+						if [[ ! -x "${musl_bad_link_path}" ]] ; then
+							continue
+						fi
+						;;
+				esac
+
+				einfo "Fixing musl libc link for ${musl_bad_link_path}"
+
+				for musl_bad_soname in "${MUSL_BAD_SONAMES[@]}" ; do
+					patchelf --remove-needed "${musl_bad_soname}" "${musl_bad_link_path}" || die
+				done
+
+				patchelf --add-needed libc.so "${musl_bad_link_path}" || die
+			done < <(find . -type f -name "${musl_bad_link}")
+		done
+	fi
+
+	# Remove static libraries, bug https://bugs.gentoo.org/825774
+	find ./packs -type f -name "libnethost.a" -delete || die
+}
+
+src_install() {
+	local dest="opt/${PN}-${SDK_SLOT}"
+	dodir "${dest%/*}"
+
+	# Create a magic workloads file, bug #841896
+	local featureband="$(( $(ver_cut 3) / 100 * 100 ))"       # e.g. 404 -> 400
+	local workloads="metadata/workloads/${SDK_SLOT}.${featureband}"
+
+	mkdir -p "${S}/${workloads}" || die
+	touch "${S}/${workloads}/userlocal" || die
+
+	mv "${S}" "${ED}/${dest}" || die
+	mkdir "${S}" || die
+
+	fperms 0755 "/${dest}"
+	dosym "../../${dest}/dotnet" "/usr/bin/dotnet-bin-${SDK_SLOT}"
+}
+
+pkg_postinst() {
+	eselect dotnet update ifunset
+}
+
+pkg_postrm() {
+	eselect dotnet update ifunset
+}