dev-lang/swi-prolog: bump development version

Package-Manager: Portage-3.0.4, Repoman-2.3.22
Signed-off-by: Keri Harris <keri@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index 1c6994be8c4f..4c5440b7c1ef 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -5,3 +5,4 @@ DIST swipl-8.2.3.tar.gz 10999577 BLAKE2B 57cfa9f6fb97f0136a35da1850c7ae8da123d1c
 DIST swipl-8.3.16.tar.gz 11123493 BLAKE2B 6d9566762b5d96a20a27dece39d895e2b29d3555dffe1d0495d8f8f579443ae2c37df2b0fe89c3fa6cc95743f55efdc6a4d6653e6cd1ba5ff8489181f8c7fc5a SHA512 ceaef49d29eac3a100e6d51e1bcc4e7925ce682ffda8bd2a668463b870a25e163c6d9e538c0cd46ffdc9a709c720ba9b31137a7c24a8087ea3bc0a1616304b00
 DIST swipl-8.3.17.tar.gz 11120834 BLAKE2B bc0c05a3305d30ec98f636e141b1d22e3ad06444ae98e7bb5b42a2a0e120effb68594f7c8af6da2fde915dfa679635c779a2a45144452e1b3598178b9e6095f5 SHA512 498fd807623d9ab596ce127a60430864faff6d803f63a77ef22fcbcd4e6ad02a9d6a528e0a782f68b9f92d3efd74838b95d72c1717b79000153f55ad4037b180
 DIST swipl-8.3.18.tar.gz 11121028 BLAKE2B 9b5bca6cb2f11918e51f687d3f330f021cc207c029e58dff7e5cbb03c47a908878c56dded8b9a4df2a67e86c2dd28400462a8484802eb18cb0eb2454a96e59a0 SHA512 6a7845c807b7ef41b501bd53d7e11208cac95bb57ac2096c8e00dd2740987faa61bf7b5201b3abf879770bc7a0935ed377458bf84de0298696741c812c009a65
+DIST swipl-8.3.19.tar.gz 11135612 BLAKE2B 89e7b4dbfca9b52217ee55439bb6892344d322b4d99719755fb34f9503448c4d3b018d73a95094c31f51cb514ee09121822b579d6c94969ebad6553548136bbd SHA512 1b2acc0006f2d29113ffa51595b53883e7c903419c47ea137954922241f03ce5d6c28e07e4e4d89da228db531af9e42678cd36fcd854495b8d091e809c8e249b
diff --git a/dev-lang/swi-prolog/swi-prolog-8.3.19.ebuild b/dev-lang/swi-prolog/swi-prolog-8.3.19.ebuild
new file mode 100644
index 000000000000..c9064992abbc
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.3.19.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		eapply "${WORKDIR}"/${PV}
+	fi
+	eapply_user
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+	sed -i -e "s|\(SWIPL_INSTALL_CMAKE_CONFIG_DIR\) lib/|\1   $(get_libdir)/|" CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	XDG_CONFIG_DIRS="${HOME}" \
+	XDG_DATA_DIRS="${HOME}" \
+		cmake-utils_src_compile
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}