dev-libs/intel-compute-runtime: add 23.52.28202.23

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-libs/intel-compute-runtime/Manifest b/dev-libs/intel-compute-runtime/Manifest
index a5ae0bbaeb4b..152e507dff08 100644
--- a/dev-libs/intel-compute-runtime/Manifest
+++ b/dev-libs/intel-compute-runtime/Manifest
@@ -1 +1,2 @@
 DIST intel-compute-runtime-23.48.27912.9.tar.gz 6842680 BLAKE2B 599ac52a176f05a5f6770bf0be4e1f899a9ea378b3a5ef2bc13f61e9706a3abfc7c8c2ebc7c17e64baf71f0bb73904ef80b1c0391d91790ae1db81f7fc5d5c03 SHA512 8c8fa6aa40f25871d9b2b61035c1a539d18d2f521424e925ecdcd89336b948e24784ae0a795811e0defeb6c295e7b175e4af525d4fcb24bd62852f6cd07584af
+DIST intel-compute-runtime-23.52.28202.23.tar.gz 6903413 BLAKE2B ecd16511fc8065cc8e09827a1b333a5d8caa1ec0c815de21b90d896a5d1e6c8225423e748005b5f6012eb0c68da08cf06abaf8431709145bb329a3dd34270222 SHA512 aa33b712af2526f94a3d8508edb3201203c34bf90b0125ed9b9878539066baaedd9b9e1c464b760c38c159b4b4aa3671465ba90c2bdd58626f578e92957093fa
diff --git a/dev-libs/intel-compute-runtime/intel-compute-runtime-23.52.28202.23.ebuild b/dev-libs/intel-compute-runtime/intel-compute-runtime-23.52.28202.23.ebuild
new file mode 100644
index 000000000000..339e0d0359be
--- /dev/null
+++ b/dev-libs/intel-compute-runtime/intel-compute-runtime-23.52.28202.23.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+l0 +vaapi"
+
+RDEPEND=">=media-libs/gmmlib-22.3.5:="
+
+DEPEND="
+	${DEPEND}
+	dev-libs/intel-metrics-discovery:=
+	dev-libs/intel-metrics-library:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-compiler-1.0.15136.4
+	>=dev-util/intel-graphics-system-controller-0.8.13:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.14.0:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-22.24.23453-remove-fortify-sources.patch"
+)
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# See https://github.com/intel/compute-runtime/issues/531
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}