dev-libs/libbpf-0.1.0-r1: Compile static lib with -fPIC (needed for bcc)

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-libs/libbpf/libbpf-0.1.0-r1.ebuild b/dev-libs/libbpf/libbpf-0.1.0-r1.ebuild
new file mode 100644
index 000000000000..1c2508425132
--- /dev/null
+++ b/dev-libs/libbpf/libbpf-0.1.0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic toolchain-funcs
+
+if [[ ${PV} =~ [9]{4,} ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/libbpf/libbpf.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+S="${WORKDIR}/${P}/src"
+
+HOMEPAGE="https://github.com/libbpf/libbpf"
+DESCRIPTION="Stand-alone build of libbpf from the Linux kernel"
+
+LICENSE="GPL-2 LGPL-2.1 BSD-2"
+SLOT="0/${PV}"
+IUSE="+static-libs"
+
+COMMON_DEPEND="virtual/libelf
+	!<=dev-util/bcc-0.7.0"
+DEPEND="${COMMON_DEPEND}
+	sys-kernel/linux-headers"
+RDEPEND="${COMMON_DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/libbpf-0.0.7-paths.patch"
+)
+
+src_compile() {
+	append-cflags -fPIC
+	emake \
+		BUILD_SHARED=y \
+		LIBSUBDIR="$(get_libdir)" \
+		$(usex static-libs 'BUILD_STATIC=y' '' '' '') \
+		CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake \
+		BUILD_SHARED=y \
+		LIBSUBDIR="$(get_libdir)" \
+		DESTDIR="${D}" \
+		$(usex static-libs 'BUILD_STATIC=y' '' '' '') \
+		install install_uapi_headers
+
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+}