dev-libs/librevenge: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 17 insertions, 22 deletions

diff --git a/dev-libs/librevenge/librevenge-0.0.4-r1.ebuild b/dev-libs/librevenge/librevenge-0.0.4-r2.ebuild
index 14145f8a95a9..8859233f807d 100644
--- a/dev-libs/librevenge/librevenge-0.0.4-r1.ebuild
+++ b/dev-libs/librevenge/librevenge-0.0.4-r2.ebuild
@@ -1,52 +1,47 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=8
 
-inherit flag-o-matic multilib-minimal
+inherit multilib-minimal
 
-DESCRIPTION="A helper library for REVerse ENGineered formats filters"
-HOMEPAGE="https://sf.net/p/libwpd/librevenge"
 if [[ ${PV} == *9999 ]] ; then
-	EGIT_REPO_URI="git://git.code.sf.net/p/libwpd/librevenge"
+	EGIT_REPO_URI="https://git.code.sf.net/p/libwpd/librevenge"
 	inherit git-r3 autotools
 else
 	SRC_URI="https://sf.net/projects/libwpd/files/${PN}/${P}/${P}.tar.xz"
 	KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~sparc x86"
 fi
 
+DESCRIPTION="Helper library for REVerse ENGineered formats filters"
+HOMEPAGE="https://sf.net/p/libwpd/librevenge"
+
 LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
 SLOT="0"
 IUSE="doc test"
 RESTRICT="!test? ( test )"
 
-RDEPEND="
-	sys-libs/zlib[${MULTILIB_USEDEP}]
-"
+RDEPEND="sys-libs/zlib[${MULTILIB_USEDEP}]"
 DEPEND="${RDEPEND}
 	dev-libs/boost
-	doc? ( app-doc/doxygen )
-	test? ( dev-util/cppunit[${MULTILIB_USEDEP}] )
-"
+	test? ( dev-util/cppunit[${MULTILIB_USEDEP}] )"
+BDEPEND="doc? ( app-doc/doxygen )"
 
 src_prepare() {
 	default
-	[[ ${PV} = *9999 ]] && eautoreconf
-
-	# bug 651264
-	append-cxxflags -std=c++11
+	[[ ${PV} == *9999 ]] && eautoreconf
 }
 
 multilib_src_configure() {
-	ECONF_SOURCE=${S} \
-	econf \
-		--disable-static \
-		--disable-werror \
-		$(use_with doc docs) \
+	local myeconfargs=(
+		--disable-werror
+		$(use_with doc docs)
 		$(use_enable test tests)
+	)
+	ECONF_SOURCE=${S} econf "${myeconfargs[@]}"
 }
 
 multilib_src_install_all() {
 	einstalldocs
-	find "${D}" -name '*.la' -delete || die
+	find "${ED}" -name '*.la' -type f -delete || die
 }