dev-python/boto: Bump

Package-Manager: portage-2.3.0

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-python/boto/boto-2.42.0.ebuild b/dev-python/boto/boto-2.42.0.ebuild
new file mode 100644
index 000000000000..532f9359b21a
--- /dev/null
+++ b/dev-python/boto/boto-2.42.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Amazon Web Services API"
+HOMEPAGE="https://github.com/boto/boto https://pypi.python.org/pypi/boto"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+REQUIRED_USE="doc? ( || ( $(python_gen_useflags 'python2*') ) )"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+# requires Amazon Web Services keys to pass some tests
+RESTRICT="test"
+
+pkg_setup() {
+	use doc && DISTUTILS_ALL_SUBPHASE_IMPLS=( 'python2*' )
+}
+
+python_test() {
+	"${PYTHON}" tests/test.py -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "s/, 'sphinx.ext.intersphinx'//" -i docs/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		# Appease the doc build and supply a file for _static
+		# the usual emake -C docs doesn't work under this authorship
+		cd docs && mkdir source/_static  || die
+		emake html
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}