proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 63 insertions, 0 deletions

diff --git a/dev-python/imapclient/imapclient-0.12.ebuild b/dev-python/imapclient/imapclient-0.12.ebuild
new file mode 100644
index 000000000000..26390b0d019e
--- /dev/null
+++ b/dev-python/imapclient/imapclient-0.12.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="IMAPClient"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="easy-to-use, pythonic, and complete IMAP client library"
+HOMEPAGE="http://imapclient.freshfoo.com/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc examples test"
+
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( $(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 pypy) )"
+
+S=${WORKDIR}/${MY_P}
+
+python_prepare_all() {
+	# use system setuptools
+	sed -i '/use_setuptools/d' setup.py || die
+
+	# drop explicit mock version test dep
+	sed -i "/tests_require/s:'mock==.\+':'mock':" setup.py || die
+
+	# use system six library. patch proven less preferable to use of sed (< maintenance)
+	# but a copy of the working hunks from prior version works fine for now.
+	rm imapclient/six.py || die
+	epatch "${FILESDIR}"/0.12-tests.patch
+	sed -e 's:from .six:from six:g' \
+		-e 's:from . import six:import six:g' \
+		-i ${PN}/*.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${PYTHON}" -m unittest discover || die "tests failed under ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+	# don't install examples and tests in module dir
+	rm -r "${D}"$(python_get_sitedir)/imapclient/{examples,test} || die
+}
+
+python_install_all() {
+#	local DOCS=( AUTHORS HACKING.rst NEWS.rst README.rst THANKS )
+	use doc && local HTML_DOCS=( doc/html/. )
+	distutils-r1_python_install_all
+	use examples && dodoc -r ${PN}/examples
+}