dev-python/keystoneauth: add 5.0.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/dev-python/keystoneauth/Manifest b/dev-python/keystoneauth/Manifest
index 85f0bd315c85..3ce0b8fe465b 100644
--- a/dev-python/keystoneauth/Manifest
+++ b/dev-python/keystoneauth/Manifest
@@ -1 +1,2 @@
 DIST keystoneauth1-4.6.0.tar.gz 267019 BLAKE2B ad1df2ce6f88ca03f1c9cde6bd84014fc7afedb3fb2375bc95461bab466f82464393e20919e4e506bce2cdbf1283ef53777c7ab3e92e2195b21d95459814f408 SHA512 fe6fbb0e47fb3608b0653362da0d19bdcb7055f9d043c776d487a2f6af76bda1cc1d8a2b87a771cafb54d0cd349695618428ed7dd93aba273d3d455b4175cbc8
+DIST keystoneauth1-5.0.0.tar.gz 267142 BLAKE2B 9c595151287c0f5eff2faa3618e97c1a540e7a2ae4bbf6b76b7ebb5b3a7d0b1443843d7ead98d1997d68ef5def7745b2eb728ff4cde7842a35d46e69b3ea15d7 SHA512 41844b669d8f355525f444b7c837aa6ad6e7efc3e7ce727b6bc6ff441d6b6b49fe8dc2d601d8135ac872484e827cec75c72b613d001f5312e077016d424dcbfa
diff --git a/dev-python/keystoneauth/keystoneauth-5.0.0.ebuild b/dev-python/keystoneauth/keystoneauth-5.0.0.ebuild
new file mode 100644
index 000000000000..ced69f35280b
--- /dev/null
+++ b/dev-python/keystoneauth/keystoneauth-5.0.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="This package contains tools for authenticating to an OpenStack-based cloud"
+HOMEPAGE="https://github.com/openstack/keystoneauth"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}1/${PN}1-${PV}.tar.gz"
+S="${WORKDIR}/${PN}1-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+CDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${CDEPEND}
+	test? (
+		>=dev-python/betamax-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/lxml-4.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oauthlib-0.6.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+		>=dev-python/requests-kerberos-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# relies on specific test runner name
+	sed -i -e 's:run\.py:unittest_or_fail.py:' \
+		keystoneauth1/tests/unit/test_session.py || die
+	# remove the test that requires hacking
+	rm keystoneauth1/tests/unit/test_hacking_checks.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	eunittest -b
+}