dev-python/pyasn1-modules: Version Bump

Package-Manager: portage-2.2.22
Signed-off-by: Justin Lecher <jlec@gentoo.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-python/pyasn1-modules/pyasn1-modules-0.0.8.ebuild b/dev-python/pyasn1-modules/pyasn1-modules-0.0.8.ebuild
new file mode 100644
index 000000000000..5c68dd2fe0b2
--- /dev/null
+++ b/dev-python/pyasn1-modules/pyasn1-modules-0.0.8.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="pyasn1 modules"
+HOMEPAGE="http://pyasn1.sourceforge.net/ https://pypi.python.org/pypi/pyasn1-modules"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE=""
+
+RDEPEND=">=dev-python/pyasn1-0.1.8[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+python_test() {
+	echoit() { echo "$@"; "$@"; }
+	local exit_status=0 test
+	for test in test/*.sh; do
+		PATH="${S}/tools:${PATH}" \
+			echoit sh "${test}" || exit_status=1
+	done
+	return ${exit_status}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	insinto /usr/share/${P}
+	doins -r tools
+}