dev-python/pytest: bump to 3.10.1

Signed-off-by: Virgil Dupras <vdupras@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

2 files changed, 66 insertions, 0 deletions

diff --git a/dev-python/pytest/Manifest b/dev-python/pytest/Manifest
index 792d33174753..a6bf98c2dd6a 100644
--- a/dev-python/pytest/Manifest
+++ b/dev-python/pytest/Manifest
@@ -1,3 +1,4 @@
+DIST pytest-3.10.1.tar.gz 892420 BLAKE2B 38849ae69bf4380bc1a99aa105cac04be078da4460373dfc16fa555238b2830fa2f5ae6c19de8aa2af9ac18d87c5d2705d62f7b2e67e4a62d843f6a28bbd76fd SHA512 30ff79c0fdcbeef68e1191ff400a20428e391717f06957f554b694b94baaaa565dca01346fe989c3e443c4402f3b2bdbd5564f6303a4447f933fb54cba45628f
 DIST pytest-3.2.2.tar.gz 786396 BLAKE2B e669da930890e902b0323ec3a6685080ddd889e74655f7b4cb08ec421651f987597021a31471aab5a32d637b99620ce7792cbdf8f85561db3bb10ff06a446ba1 SHA512 6df3a50e7d1efeaf7a283920b16d1daf800798f422bc851b0aacd2bbd5cb0a88c95f9057fae49943b9dfe6527ed552cdf8d983b944ab91d0af252ee4f6eb82db
 DIST pytest-3.4.2.tar.gz 812719 BLAKE2B 96623d6cdea4bd79778175c18c949938505f1862010f700f9a8cb85f445910381af391a5b69e664fbbfc254bf46502c798c72026772070236a0a3bca7aeeb3d6 SHA512 787065ab76d4482799bb2da9f024c9c383e68cc1cc01f3b80f6ed9444ca6383d20953615696ed4dd01668777b094cf5002b23c4ce51828879dcf8ebf2170c71b
 DIST pytest-3.6.3.tar.gz 830949 BLAKE2B 4c0df5d157b8bb0ac6261a793aac2a8074c869b1a7cbda3eda600c79648b3722eaf2a57514c1fece60e0aac324b8ed09e8e889dda268619204e9e1f1637e1c9b SHA512 e18d8e972cb1b05b037b9441eea5981ce036d8e2c2bab80f6e50f283df9bd08740296133990424cf78449f6d3d2fbd1d59709770aa972af99fe061583f2d79a7
diff --git a/dev-python/pytest/pytest-3.10.1.ebuild b/dev-python/pytest/pytest-3.10.1.ebuild
new file mode 100644
index 000000000000..7b1f51abe66f
--- /dev/null
+++ b/dev-python/pytest/pytest-3.10.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="Simple powerful testing with Python"
+HOMEPAGE="http://pytest.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc64 ~sparc ~x86 ~amd64-fbsd ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+
+# When bumping, please check setup.py for the proper py version
+PY_VER="1.5.0"
+
+# pathlib2 has been added to stdlib before py3.6, but pytest needs __fspath__
+# support, which only came in py3.6.
+RDEPEND="
+	>=dev-python/atomicwrites-1.0[${PYTHON_USEDEP}]
+	>=dev-python/attrs-17.4.0[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-4.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/pathlib2[${PYTHON_USEDEP}]' python2_7 python3_{4,5} )
+	>=dev-python/pluggy-0.7[${PYTHON_USEDEP}]
+	>=dev-python/py-${PY_VER}[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-40[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	virtual/python-funcsigs[${PYTHON_USEDEP}]"
+
+# flake & pytest-capturelog cause a number of tests to fail
+DEPEND="${RDEPEND}
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/hypothesis-3.56[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' -2)
+		dev-python/requests[${PYTHON_USEDEP}]
+		!!dev-python/flaky
+		!!dev-python/pytest-capturelog
+	)"
+
+python_prepare_all() {
+	grep -qF "py>=${PY_VER}" setup.py || die "Incorrect dev-python/py dependency"
+
+	# Something in the ebuild environment causes this to hang/error.
+	# https://bugs.gentoo.org/598442
+	rm testing/test_pdb.py || die
+
+	# those tests appear to hang with python3.5+;  TODO: investigate why
+	sed -i -e 's:test_runtest_location_shown_before_test_starts:_&:' \
+		testing/test_terminal.py || die
+	sed -i -e 's:test_trial_pdb:_&:' testing/test_unittest.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${PYTHON}" "${BUILD_DIR}"/lib/pytest.py --lsof -rfsxX \
+		-vv testing || die "tests failed with ${EPYTHON}"
+}