dev-python/sphinx: revert removal of 1.2.3-r1 ebuild

Its removal broke QA checks on ~arm64.

Signed-off-by: Virgil Dupras <vdupras@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

2 files changed, 126 insertions, 0 deletions

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 3124fdbaddfd..1aded9f30831 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,2 +1,3 @@
 DIST Sphinx-1.2.2.tar.gz 3143671 BLAKE2B a21b2a060363ac86832a6a28a623ed410ff0bb39ca3c9c58618ade88f4305996e54c559bb588c518597e31a73fc16e0c37fc57950eb077179f03715dfee72729 SHA512 44073c215f9d0e7f6c7bc91cb85b0508a96e5cfff5f940fef86e2fc6f11281d03b54e87e51e5a99a23e96b470a93f3af86a6a3ab7c317c747406c55b4c37791c
+DIST Sphinx-1.2.3.tar.gz 3200548 BLAKE2B 42033c59e6e38247af12c78cb4f69c73b1dfa883aa8a9e6c180bb74de666b45faef24a55c0bfd3aa1f22bf3e632e0e95016eb1bea54e8b5ebc7df78756763b5c SHA512 00346516e826a65145a3a7fd25ef7cee569ae7fdcc0c1bec3a7301fc08d5d8730d02eee792c3efedfcac17e712ea7e2ad70ea1fcdedc11720ad54f6bcb51ad05
 DIST Sphinx-1.7.5.tar.gz 4726802 BLAKE2B 8d828dcae1f3ebb813c5f2de8c096a3fac4ab88b424955c27592349c544b775a21703c904a54efa7f86e1967198f4950804904a82a7142a3499f33c5343506e3 SHA512 db2a8df2cdb2ed78ce2341175575c2b04a149451b2bc8a4f74ddc73e308a19d505874fdbae4e370ce48a9b1cdb4de47cdab489bc57c1b378e857d5b8d04a07b8
diff --git a/dev-python/sphinx/sphinx-1.2.3-r1.ebuild b/dev-python/sphinx/sphinx-1.2.3-r1.ebuild
new file mode 100644
index 000000000000..225e80dc9d88
--- /dev/null
+++ b/dev-python/sphinx/sphinx-1.2.3-r1.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 eutils versionator
+
+MY_PN="Sphinx"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="http://sphinx.pocoo.org/ https://pypi.org/project/Sphinx/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc latex test"
+
+# Portage has only >= minimum required versions of all rdeps making
+# setting of version borders unnecessary
+RDEPEND="
+	<dev-python/docutils-0.13[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	latex? (
+		dev-texlive/texlive-latexextra
+		app-text/dvipng
+	)"
+DEPEND="${DEPEND}
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile() {
+	distutils-r1_python_compile
+
+	# Generate the grammar. It will be caught by install somehow.
+	# Note that the tests usually do it for us. However, I don't want
+	# to trust USE=test really running all the tests, especially
+	# with FEATURES=test-fail-continue.
+	pushd "${BUILD_DIR}"/lib > /dev/null || die
+	"${PYTHON}" -m sphinx.pycode.__init__ \
+		|| die "Grammar generation failed."
+	popd > /dev/null || die
+}
+
+python_compile_all() {
+	use doc && emake -C doc SPHINXBUILD='"${PYTHON}" "${S}/sphinx-build.py"' html
+}
+
+python_test() {
+	cp -r -l tests "${BUILD_DIR}"/ || die
+
+	if $(python_is_python3); then
+		2to3 -w --no-diffs "${BUILD_DIR}"/tests || die
+	fi
+
+	nosetests -w "${BUILD_DIR}"/tests -v \
+		|| die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_python_install_all
+}
+
+replacing_python_eclass() {
+	local pv
+	for pv in ${REPLACING_VERSIONS}; do
+		if ! version_is_at_least 1.1.3-r4 ${pv}; then
+			return 0
+		fi
+	done
+
+	return 1
+}
+
+pkg_preinst() {
+	if replacing_python_eclass; then
+		# the old python.eclass ebuild will want to remove our pickles...
+		backup_pickle() {
+			# array to enable filename expansion
+			local pickle_name=(
+				"${D}$(python_get_sitedir)"/sphinx/pycode/Grammar*.pickle
+			)
+
+			local dest=${ROOT}${pickle_name[0]#${D}}.backup
+
+			eumask_push 022
+			mkdir -p "${dest%/*}" || die
+			eumask_pop
+
+			cp -p -v "${pickle_name[0]}" "${dest}" \
+				|| die "Unable to backup grammar pickle from overwriting"
+		}
+
+		python_foreach_impl backup_pickle
+	fi
+}
+
+pkg_postinst() {
+	if replacing_python_eclass; then
+		local warned
+
+		restore_pickle() {
+			local backup_name=(
+				"${ROOT}$(python_get_sitedir)"/sphinx/pycode/Grammar*.pickle.backup
+			)
+			local dest=${backup_name[0]%.backup}
+
+			mv -v "${backup_name[0]}" "${dest}" \
+				|| die "Unable to restore grammar pickle backup"
+		}
+
+		python_foreach_impl restore_pickle
+
+		[[ ${warned} ]] && ewarn "Please try rebuilding the package."
+	fi
+}