dev-python/trio: Bump to 0.23.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/dev-python/trio/Manifest b/dev-python/trio/Manifest
index f3d7406ac47e..59f0a7b69372 100644
--- a/dev-python/trio/Manifest
+++ b/dev-python/trio/Manifest
@@ -1 +1,2 @@
 DIST trio-0.23.1.gh.tar.gz 585734 BLAKE2B 07a03f9ddd26f4e69bda651bc0821bb02895a244400cc5ec829b82e027304722248f7cf608bad8afb928e54736034349d736ca1aaa40b470cbbc3c1a74e3c77c SHA512 e7348cefb364689060c32987120c50081c677531fb4082a68956c431112b9966af6db09ebdca036980af660e48c2bc8addd05b58d62678d45ed7ffa1ce862dcc
+DIST trio-0.23.2.gh.tar.gz 592068 BLAKE2B 4f985c03528343f6091988984b081399f4a661f73896af13b4face0c7eab242d763d4ae964d36f8c9d0fcce797518283a492edd556a83af10502c8fc617cdb91 SHA512 a77b2a20459eb4989e9db6d21b06472b3cce51f4cb28cc6f3ab2f3e1684b3ccb37775e0d60af1f121c63a54fb92d62955f76109c922879234f0a21ce8c9f20c1
diff --git a/dev-python/trio/trio-0.23.2.ebuild b/dev-python/trio/trio-0.23.2.ebuild
new file mode 100644
index 000000000000..3e69d96168ca
--- /dev/null
+++ b/dev-python/trio/trio-0.23.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+	https://github.com/python-trio/trio/
+	https://pypi.org/project/trio/
+"
+SRC_URI="
+	https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-20.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/exceptiongroup[${PYTHON_USEDEP}]
+	' 3.10)
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	>=dev-python/sniffio-1.3.0[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+# Bug https://bugs.gentoo.org/916756
+# distutils_enable_sphinx docs/source \
+# 	dev-python/immutables \
+# 	dev-python/sphinxcontrib-trio \
+# 	dev-python/sphinx-rtd-theme \
+# 	dev-python/towncrier
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Times out on slower arches (ia64 in this case)
+		# https://github.com/python-trio/trio/issues/1753
+		tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+		# requires ruff
+		_tests/tools/test_gen_exports.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	rm -rf trio || die
+	epytest -p trio._tests.pytest_plugin \
+		-m "not redistributors_should_skip" \
+		--pyargs trio \
+		--skip-optional-imports
+}