dev-python/pyGPG: add 0.2_p20220808

Snapshot which has tests so let's add Python 3.11 to it as well.

Closes: https://bugs.gentoo.org/896822
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 72 insertions, 2 deletions

diff --git a/dev-python/pyGPG/Manifest b/dev-python/pyGPG/Manifest
index b05cbd55dc19..9f6ec7e8ff54 100644
--- a/dev-python/pyGPG/Manifest
+++ b/dev-python/pyGPG/Manifest
@@ -1 +1,2 @@
 DIST pyGPG-0.2.tar.gz 15439 BLAKE2B 92c82b8b23c279461a872f118c636fa9cdae3f44910fc34a357983b0b4afea2a7b13c6400499a0fdbb4365357ade64294642178ca07a79ab3b7df89e60146e73 SHA512 93d892a57a27b254bfdc9778b73d341dfec654c2104c578014628df78c43beaf93eafb571ac544d52f334e63f6e5b8c0cfad7c8a0d585ee7211e8649efce8c67
+DIST pyGPG-0.2_p20220808.gh.tar.gz 31955 BLAKE2B ae671b7bf685b1072364dbfcf79bca8fa2dadd034fbdf7a721d7a2cfec44e8d8ffa22b08c14414c8774422b6a62af8d511bd31bd15bd68d89632cde031ec0906 SHA512 85c8d67e71e91cfb26b1e0087889d7cd4fccae9ddcffcd3e3f9d208da7fd352c3273c580e3b7c284c5ab4c2a53c56f4530e5587dc22869098a408a1dfcd1e257
diff --git a/dev-python/pyGPG/pyGPG-0.2_p20220808.ebuild b/dev-python/pyGPG/pyGPG-0.2_p20220808.ebuild
new file mode 100644
index 000000000000..6749e63d1904
--- /dev/null
+++ b/dev-python/pyGPG/pyGPG-0.2_p20220808.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/dol-sen/pyGPG.git"
+	EGIT_BRANCH="master"
+elif [[ ${PV} == *_p* ]] ; then
+	MY_COMMIT="eb44ec69978044809325a0a9c8972d1d4f573b47"
+	SRC_URI="https://github.com/dol-sen/pyGPG/archive/${MY_COMMIT}.tar.gz -> ${P}.gh.tar.gz"
+	S="${WORKDIR}"/${PN}-${MY_COMMIT}
+else
+	SRC_URI="https://dev.gentoo.org/~dolsen/releases/pyGPG/${P}.tar.gz"
+fi
+
+DESCRIPTION="A python interface wrapper for gnupg's gpg command"
+HOMEPAGE="https://github.com/dol-sen/pyGPG"
+
+LICENSE="BSD"
+SLOT="0"
+if [[ ${PV} != *9999 ]] ; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+RDEPEND="app-crypt/gnupg"
+
+EPYTEST_DESELECT=(
+	# Expired keys
+	test/pyGPG/test_gpg.py::test_listkeys2
+	test/pyGPG/test_gpg.py::test_listkey2
+	test/pyGPG/test_gpg.py::test_listkey
+	test/pyGPG/test_gpg.py::test_fingerprint2
+)
+
+distutils_enable_tests pytest
+
+pkg_postinst() {
+	elog "This is experimental software."
+	elog "The APIs it installs should be considered unstable"
+	elog "and are subject to change."
+	elog
+	elog "Please file any enhancement requests, or bugs"
+	elog "at https://github.com/dol-sen/pyGPG/issues"
+	elog "I am also on IRC @ #gentoo-ci of the Libera.Chat network"
+	elog
+	ewarn "There may be some Python 3 compatibility issues still."
+	ewarn "Please help debug/fix/report them in github or bugzilla."
+}
diff --git a/dev-python/pyGPG/pyGPG-9999.ebuild b/dev-python/pyGPG/pyGPG-9999.ebuild
index 337db049369c..6749e63d1904 100644
--- a/dev-python/pyGPG/pyGPG-9999.ebuild
+++ b/dev-python/pyGPG/pyGPG-9999.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9,10} )
+PYTHON_COMPAT=( python3_{9..11} )
 
 inherit distutils-r1
 
@@ -12,9 +12,12 @@ if [[ ${PV} == *9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/dol-sen/pyGPG.git"
 	EGIT_BRANCH="master"
+elif [[ ${PV} == *_p* ]] ; then
+	MY_COMMIT="eb44ec69978044809325a0a9c8972d1d4f573b47"
+	SRC_URI="https://github.com/dol-sen/pyGPG/archive/${MY_COMMIT}.tar.gz -> ${P}.gh.tar.gz"
+	S="${WORKDIR}"/${PN}-${MY_COMMIT}
 else
 	SRC_URI="https://dev.gentoo.org/~dolsen/releases/pyGPG/${P}.tar.gz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 fi
 
 DESCRIPTION="A python interface wrapper for gnupg's gpg command"
@@ -22,9 +25,20 @@ HOMEPAGE="https://github.com/dol-sen/pyGPG"
 
 LICENSE="BSD"
 SLOT="0"
+if [[ ${PV} != *9999 ]] ; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
 
 RDEPEND="app-crypt/gnupg"
 
+EPYTEST_DESELECT=(
+	# Expired keys
+	test/pyGPG/test_gpg.py::test_listkeys2
+	test/pyGPG/test_gpg.py::test_listkey2
+	test/pyGPG/test_gpg.py::test_listkey
+	test/pyGPG/test_gpg.py::test_fingerprint2
+)
+
 distutils_enable_tests pytest
 
 pkg_postinst() {