dev-qt/designer: 5.15.10 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 59 insertions, 0 deletions

diff --git a/dev-qt/designer/designer-5.15.10.ebuild b/dev-qt/designer/designer-5.15.10.ebuild
new file mode 100644
index 000000000000..e3babb8e34b9
--- /dev/null
+++ b/dev-qt/designer/designer-5.15.10.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} != *9999* ]]; then
+	QT5_KDEPATCHSET_REV=1
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+QT5_MODULE="qttools"
+inherit desktop qt5-build xdg-utils
+
+DESCRIPTION="WYSIWYG tool for designing and building graphical user interfaces with QtWidgets"
+
+IUSE="declarative"
+
+DEPEND="
+	=dev-qt/qtcore-${QT5_PV}*:5=
+	=dev-qt/qtgui-${QT5_PV}*:5=[png]
+	=dev-qt/qtnetwork-${QT5_PV}*
+	=dev-qt/qtprintsupport-${QT5_PV}*
+	=dev-qt/qtwidgets-${QT5_PV}*
+	=dev-qt/qtxml-${QT5_PV}*
+	declarative? ( =dev-qt/qtdeclarative-${QT5_PV}*[widgets] )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/designer
+)
+
+src_prepare() {
+	qt_use_disable_mod declarative quickwidgets \
+		src/designer/src/plugins/plugins.pro
+
+	sed -e "s/qtHaveModule(webkitwidgets)/false/g" \
+		-i src/designer/src/plugins/plugins.pro || die
+
+	qt5-build_src_prepare
+}
+
+src_install() {
+	qt5-build_src_install
+	qt5_symlink_binary_to_path designer 5
+
+	doicon -s 128 src/designer/src/designer/images/designer.png
+	make_desktop_entry "${QT5_BINDIR}"/designer 'Qt 5 Designer' designer 'Qt;Development;GUIDesigner'
+}
+
+pkg_postinst() {
+	qt5-build_pkg_postinst
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	qt5-build_pkg_postrm
+	xdg_icon_cache_update
+}