dev-qt/qtcore: 5.15.4 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 104 insertions, 0 deletions

diff --git a/dev-qt/qtcore/Manifest b/dev-qt/qtcore/Manifest
index 9493fb380547..876cb884f820 100644
--- a/dev-qt/qtcore/Manifest
+++ b/dev-qt/qtcore/Manifest
@@ -1,2 +1,4 @@
 DIST qtbase-5.15.3-gentoo-kde-1.tar.xz 337032 BLAKE2B a5a3ff6c6002e386d15dd3122faec8e09fba19df12db59a6cdff1f04b7cc9919cf5cc30f4ae936ee3cb29cf110e714bb727929330ced292b699472367adfef4c SHA512 042743816f3c08dc3313be76da31e206c37dd7dc5b2604b36ef4be18ad66a89d9d29a61f9cccaa169665f742f7fbfb60822189e8cab0d23f3d4efe293a79f78c
+DIST qtbase-5.15.4-gentoo-kde-1.tar.xz 507288 BLAKE2B a22d3745d3c690e29f7726cc464e3721777768e6e4f937e84ee2d2e14a13bcf7724e0c30b2cf4277c9ac7dadc1078545e14fb5459fbc3acc7259fb3e39e2f417 SHA512 a52bdf189e4c0fe341c2db0a5923a3600503d8eaa0c3693923a02a0ab4fa6dfc1beb21067f4723fcf2e4d7c71e39a496bf34e109e1e1c8c42922ff53f6712373
 DIST qtbase-everywhere-opensource-src-5.15.3.tar.xz 50204364 BLAKE2B 9c011e8d6033e340a1d7be6bd9100a05d55638cfd53f647752853382574b6c444668eae36bf88cfedde0e7c0e00ecb1f91d025fc59c23be5438ba0ef91a5246c SHA512 01723eff5116a1d7d136fa32d2aee2691b227a241dbc160953ee72a8c0f3bc7ab771c17434629cabef419983ef43bb38aa6956ddcc09c9a82e116a50073b0079
+DIST qtbase-everywhere-opensource-src-5.15.4.tar.xz 50225468 BLAKE2B 3525126791ca168ea4227bc58bef0202f4cec68396c958b0e7f09e7b41ca9d70bbcf0e78b5e7997bc3e4a59e889128f93964b5d0a9db7d012403581cff3dc30b SHA512 91a1d95c2891939ae55134e8897cbc423142bd8eda954a1e65bb563b0932ed9e2da34db374fd86858b4a819e8abe824a967b31f4fb316528ec8aaf15016c6ad3
diff --git a/dev-qt/qtcore/qtcore-5.15.4.ebuild b/dev-qt/qtcore/qtcore-5.15.4.ebuild
new file mode 100644
index 000000000000..ed8758faba13
--- /dev/null
+++ b/dev-qt/qtcore/qtcore-5.15.4.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QT5_KDEPATCHSET_REV=1
+QT5_MODULE="qtbase"
+inherit linux-info qt5-build
+
+DESCRIPTION="Cross-platform application development framework"
+SLOT=5/${QT5_PV}
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+IUSE="icu old-kernel systemd"
+
+DEPEND="
+	dev-libs/double-conversion:=
+	dev-libs/glib:2
+	dev-libs/libpcre2[pcre16,unicode]
+	sys-libs/zlib:=
+	icu? ( dev-libs/icu:= )
+	!icu? ( virtual/libiconv )
+	systemd? ( sys-apps/systemd:= )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/tools/bootstrap
+	src/tools/moc
+	src/tools/rcc
+	src/corelib
+	src/tools/qlalr
+	doc
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	!:network
+	!:sql
+	!:testlib
+	!:xml
+)
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.15.3-pthread.patch # bug 803470
+)
+
+pkg_pretend() {
+	use kernel_linux || return
+	get_running_version
+	if kernel_is -lt 4 11 && ! use old-kernel; then
+		ewarn "The running kernel is older than 4.11. USE=old-kernel is needed for"
+		ewarn "dev-qt/qtcore to function on this kernel properly. Bugs #669994, #672856"
+	fi
+}
+
+src_prepare() {
+	# don't add -O3 to CXXFLAGS, bug 549140
+	sed -i -e '/CONFIG\s*+=/s/optimize_full//' src/corelib/corelib.pro || die
+
+	# fix missing qt_version_tag symbol w/ LTO, bug 674382
+	sed -i -e 's/^gcc:ltcg/gcc/' src/corelib/global/global.pri || die
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myconf=(
+		$(qt_use icu)
+		$(qt_use !icu iconv)
+		$(qt_use systemd journald)
+	)
+	use old-kernel && myconf+=(
+		-no-feature-renameat2 # needs Linux 3.16, bug 669994
+		-no-feature-getentropy # needs Linux 3.17, bug 669994
+		-no-feature-statx # needs Linux 4.11, bug 672856
+	)
+	qt5-build_src_configure
+}
+
+src_install() {
+	qt5-build_src_install
+	qt5_symlink_binary_to_path qmake 5
+
+	local flags=(
+		DBUS FREETYPE IMAGEFORMAT_JPEG IMAGEFORMAT_PNG
+		OPENGL OPENSSL SSL WIDGETS
+	)
+
+	for flag in ${flags[@]}; do
+		cat >> "${D}"/${QT5_HEADERDIR}/QtCore/qconfig.h <<- _EOF_ || die
+
+			#if defined(QT_NO_${flag}) && defined(QT_${flag})
+			# undef QT_NO_${flag}
+			#elif !defined(QT_NO_${flag}) && !defined(QT_${flag})
+			# define QT_NO_${flag}
+			#endif
+		_EOF_
+	done
+}