gnome-base/librsvg: remove old

Bug: https://bugs.gentoo.org/625860
Package-Manager: Portage-2.3.8, Repoman-2.3.2

2 files changed, 0 insertions, 98 deletions

diff --git a/gnome-base/librsvg/Manifest b/gnome-base/librsvg/Manifest
index 70377dd4aa7d..5d33e3e9c3fb 100644
--- a/gnome-base/librsvg/Manifest
+++ b/gnome-base/librsvg/Manifest
@@ -1,2 +1 @@
-DIST librsvg-2.40.17.tar.xz 573244 SHA256 e6f6c5cbecc405bb945c7cd15061276035ae3173bbb3bb25e8a916779c7f69cc SHA512 296e623adbf1e833a9b1f11257a911671d6c01568719ff48f8e2a9e0bf8166eae242d0ae23243a9ac335540fff6b6cdd4760ca2f37f8afe188783fd9b1099ef5 WHIRLPOOL 64c188903faa3144703cbeba3f8736c1ff8751006f744f4a3a796e1eae9d50e633cb48ab036e55c8222edc2b8e7dc708578c7a5add8f9b96f8183e89eb8026ec
 DIST librsvg-2.40.18.tar.xz 574384 SHA256 bfc8c488c89c1e7212c478beb95c41b44701636125a3e6dab41187f1485b564c SHA512 faf503d0d881801ce129715e7ae979ee1675bd32beac9170b1889c94aac64caf486968bc86f3480463b84e94f28c1d805551ffdcb7068ecadd0688146e0fb182 WHIRLPOOL 123299a0896a7f1fb084c360f1ebe813d5b35886ae2587678a1773ffd3705305b2a30223bd61a524662076b029bdf1cb0cc0a8573bad7ba86ac99389a45e6e56
diff --git a/gnome-base/librsvg/librsvg-2.40.17.ebuild b/gnome-base/librsvg/librsvg-2.40.17.ebuild
deleted file mode 100644
index 7eb90124e50f..000000000000
--- a/gnome-base/librsvg/librsvg-2.40.17.ebuild
+++ /dev/null
@@ -1,97 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-GNOME2_LA_PUNT="yes"
-VALA_USE_DEPEND="vapigen"
-
-inherit autotools eutils gnome2 multilib-minimal vala
-
-DESCRIPTION="Scalable Vector Graphics (SVG) rendering library"
-HOMEPAGE="https://wiki.gnome.org/Projects/LibRsvg"
-
-LICENSE="LGPL-2"
-SLOT="2"
-KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
-
-IUSE="+introspection tools vala"
-REQUIRED_USE="vala? ( introspection )"
-
-RDEPEND="
-	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
-	>=x11-libs/cairo-1.12.14-r4[${MULTILIB_USEDEP}]
-	>=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}]
-	>=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
-	>=dev-libs/libcroco-0.6.8-r1[${MULTILIB_USEDEP}]
-	>=x11-libs/gdk-pixbuf-2.30.7:2[introspection?,${MULTILIB_USEDEP}]
-	introspection? ( >=dev-libs/gobject-introspection-0.10.8:= )
-	tools? ( >=x11-libs/gtk+-3.10.0:3 )
-"
-DEPEND="${RDEPEND}
-	dev-libs/gobject-introspection-common
-	dev-libs/vala-common
-	>=dev-util/gtk-doc-am-1.13
-	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
-	vala? ( $(vala_depend) )
-"
-# >=gtk-doc-am-1.13, gobject-introspection-common, vala-common needed by eautoreconf
-
-src_prepare() {
-	# https://bugzilla.gnome.org/show_bug.cgi?id=653323
-	eapply "${FILESDIR}/${PN}-2.40.12-gtk-optional.patch"
-
-	# https://bugzilla.gnome.org/show_bug.cgi?id=731826
-	eapply "${FILESDIR}/${PN}-2.40.2-vala-out-of-source.patch"
-
-	eautoreconf
-
-	use vala && vala_src_prepare
-	gnome2_src_prepare
-}
-
-multilib_src_configure() {
-	local myconf=()
-
-	# -Bsymbolic is not supported by the Darwin toolchain
-	if [[ ${CHOST} == *-darwin* ]]; then
-		myconf+=( --disable-Bsymbolic )
-	fi
-
-	# --disable-tools even when USE=tools; the tools/ subdirectory is useful
-	# only for librsvg developers
-	ECONF_SOURCE=${S} \
-	gnome2_src_configure \
-		--disable-static \
-		--disable-tools \
-		$(multilib_native_use_enable introspection) \
-		$(multilib_native_use_with tools gtk3) \
-		$(multilib_native_use_enable vala) \
-		--enable-pixbuf-loader \
-		"${myconf[@]}"
-
-	if multilib_is_native_abi; then
-		ln -s "${S}"/doc/html doc/html || die
-	fi
-}
-
-multilib_src_compile() {
-	# causes segfault if set, see bug #411765
-	unset __GL_NO_DSO_FINALIZER
-	gnome2_src_compile
-}
-
-multilib_src_install() {
-	gnome2_src_install
-}
-
-pkg_postinst() {
-	# causes segfault if set, see bug 375615
-	unset __GL_NO_DSO_FINALIZER
-	multilib_foreach_abi gnome2_pkg_postinst
-}
-
-pkg_postrm() {
-	# causes segfault if set, see bug 375615
-	unset __GL_NO_DSO_FINALIZER
-	multilib_foreach_abi gnome2_pkg_postrm
-}