gnome-extra/gnome-power-manager: version bump 3.22.2 → 3.24.0

Port away from intltool. Translation updates.

Package-Manager: Portage-2.3.6, Repoman-2.3.3

1 files changed, 54 insertions, 0 deletions

diff --git a/gnome-extra/gnome-power-manager/gnome-power-manager-3.24.0.ebuild b/gnome-extra/gnome-power-manager/gnome-power-manager-3.24.0.ebuild
new file mode 100644
index 000000000000..2b21ce1ba41e
--- /dev/null
+++ b/gnome-extra/gnome-power-manager/gnome-power-manager-3.24.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2 virtualx
+
+DESCRIPTION="GNOME power management service"
+HOMEPAGE="https://projects.gnome.org/gnome-power-manager/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="test"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.45.8:2
+	>=x11-libs/gtk+-3.3.8:3
+	>=x11-libs/cairo-1
+	>=sys-power/upower-0.99:=
+"
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-sgml-dtd:4.1
+	app-text/docbook-sgml-utils
+	dev-libs/appstream-glib
+	>=sys-devel/gettext-0.19.7
+	x11-proto/randrproto
+	virtual/pkgconfig
+	test? ( sys-apps/dbus )
+"
+
+# docbook-sgml-utils and docbook-sgml-dtd-4.1 used for creating man pages
+# (files under ${S}/man).
+# docbook-xml-dtd-4.4 and -4.1.2 are used by the xml files under ${S}/docs.
+
+src_prepare() {
+	# Drop debugger CFLAGS from configure
+	# Touch configure.ac only if running eautoreconf, otherwise
+	# maintainer mode gets triggered -- even if the order is correct
+	sed -e 's:^CPPFLAGS="$CPPFLAGS -g"$::g' \
+		-i configure || die "debugger sed failed"
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable test tests)
+}
+
+src_test() {
+	virtx emake check
+}