kde-apps/kwave: 23.08.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index b98a64096f66..9e39b348276b 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-23.04.3.tar.xz 6964584 BLAKE2B 2fed0b6a53bd9454ec67f4d8c28746b002e4f9889f6f8ed8ba46b42f000cf662a01a3611519d238d4e366661b601c3605b3e1bba346adfc0acb2fd3ef4b45b5d SHA512 e037df147082212fe6d2375cc9adf410a71d68c1e30583e4b0b3e6f295444a3a629f06c204349b5e0928c7da989a621e5e519185779287a8a8807b31363c9d7b
 DIST kwave-23.08.1.tar.xz 6965216 BLAKE2B a36965c43358cd70e5cd45c422154bf00190d1ae5c3fcab5c2fc5f196d843e4d8896d0f06214988803f198543478edafa014f89d6c4a0987453f2b93d94d434d SHA512 069aeebe0fe4e790fcfd3800b189a26bc18fdf3bb41f58c57326ee2b45d7f90c0b038d6eb937ec264b09518ee7427ee2edcd4b7f53d1b7e053629c893ad639b5
+DIST kwave-23.08.2.tar.xz 6965200 BLAKE2B dedad68ec025a26b330181a333615aec0a5396f2544886b32c3f63d6b72b3cdf4f265c6971ad54904f89f631d4dc179fd763ff59eee98c4793890e99e39ab89c SHA512 64ea551138c858ea9a5d6f13997ea2050541b6634209c9ce6b0c62bec5913929992aa3e31843ee3c3499d7a9f63446a599fe469a0fc8bf1e9bf8fba7a73e8dbe
diff --git a/kde-apps/kwave/kwave-23.08.2.ebuild b/kde-apps/kwave/kwave-23.08.2.ebuild
new file mode 100644
index 000000000000..11a333ca9de7
--- /dev/null
+++ b/kde-apps/kwave/kwave-23.08.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3:=
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac:=[cxx] )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-libs/libpulse )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}