kde-plasma/plasma-workspace: drop 5.21.1*

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 202 deletions

diff --git a/kde-plasma/plasma-workspace/Manifest b/kde-plasma/plasma-workspace/Manifest
index 3b8d2b10448f..34aaf5dea3e3 100644
--- a/kde-plasma/plasma-workspace/Manifest
+++ b/kde-plasma/plasma-workspace/Manifest
@@ -1,3 +1,2 @@
 DIST plasma-workspace-5.20.5.tar.xz 9041964 BLAKE2B b0bef6f74999d503064d55fdc670bd320a141c4619c0cfb7491158485096dfd636ad31dfbb4e9d7be3d86eca7b52bce97acb7aefe57377cce9e6a5ce1ad3cb9b SHA512 bd63502fdaa79deb380d254a3649a2810e4b2c6e748e9a38606f561cc46573a6e75631584a340a220742135f4682f9deea28c78b7fe4ad88ee6491f190b3212f
-DIST plasma-workspace-5.21.1.tar.xz 9711648 BLAKE2B 2a8a483d54596f115cc51a6a95ef2e228266b30650be5f1f45c3b65ca6682005edfab031aa2926b1870a09981949f6b5220dcfc197c3476debb9b8c39fa17786 SHA512 5b7f299542c66e6f387267251d8a434c773dea365d80f4a06156c3060d829e00dd283d1a5251c4168e071691e746d78968b4e8022c459b0e9cb4de80a1a5e8f2
 DIST plasma-workspace-5.21.2.tar.xz 9712516 BLAKE2B 6b355cc1c654cad00aca204c43b887140444e172e6aae38b216bde4fa60c69a6a6d996e7190d892eb5e2768f2b250232329686f5da1964d7731808d4d6949c05 SHA512 234f40bdecdbb63df065ffa9a59b0acfd6e796fa9a66b7116de50cdbb78f3333b6247f7c0e4f68ed4e3d8b3b0eea6b7a7bf65deb1ab0c933008cc59bcef61fc8
diff --git a/kde-plasma/plasma-workspace/plasma-workspace-5.21.1.ebuild b/kde-plasma/plasma-workspace/plasma-workspace-5.21.1.ebuild
deleted file mode 100644
index f5bd3552dddc..000000000000
--- a/kde-plasma/plasma-workspace/plasma-workspace-5.21.1.ebuild
+++ /dev/null
@@ -1,201 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="forceoptional"
-KFMIN=5.78.0
-PVCUT=$(ver_cut 1-3)
-QTMIN=5.15.2
-VIRTUALX_REQUIRED="test"
-inherit ecm kde.org
-
-DESCRIPTION="KDE Plasma workspace"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
-IUSE="appstream +calendar +fontconfig geolocation gps qalculate screencast +semantic-desktop systemd telemetry"
-
-REQUIRED_USE="gps? ( geolocation )"
-RESTRICT+=" test"
-
-BDEPEND="virtual/pkgconfig"
-COMMON_DEPEND="
-	>=dev-libs/wayland-1.15
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
-	>=dev-qt/qtgui-${QTMIN}:5=[jpeg]
-	>=dev-qt/qtnetwork-${QTMIN}:5
-	>=dev-qt/qtsql-${QTMIN}:5
-	>=dev-qt/qtsvg-${QTMIN}:5
-	>=dev-qt/qtwayland-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=dev-qt/qtx11extras-${QTMIN}:5
-	>=dev-qt/qtxml-${QTMIN}:5
-	>=kde-frameworks/kactivities-${KFMIN}:5
-	>=kde-frameworks/kactivities-stats-${KFMIN}:5
-	>=kde-frameworks/kauth-${KFMIN}:5
-	>=kde-frameworks/kbookmarks-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/kdeclarative-${KFMIN}:5
-	>=kde-frameworks/kded-${KFMIN}:5
-	>=kde-frameworks/kdelibs4support-${KFMIN}:5
-	>=kde-frameworks/kglobalaccel-${KFMIN}:5
-	>=kde-frameworks/kguiaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kiconthemes-${KFMIN}:5
-	>=kde-frameworks/kidletime-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kitemmodels-${KFMIN}:5
-	>=kde-frameworks/kitemviews-${KFMIN}:5
-	>=kde-frameworks/kjobwidgets-${KFMIN}:5
-	>=kde-frameworks/knewstuff-${KFMIN}:5
-	>=kde-frameworks/knotifications-${KFMIN}:5
-	>=kde-frameworks/knotifyconfig-${KFMIN}:5
-	>=kde-frameworks/kpackage-${KFMIN}:5
-	>=kde-frameworks/kpeople-${KFMIN}:5
-	>=kde-frameworks/krunner-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/ktexteditor-${KFMIN}:5
-	>=kde-frameworks/ktextwidgets-${KFMIN}:5
-	>=kde-frameworks/kwallet-${KFMIN}:5
-	>=kde-frameworks/kwayland-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kwindowsystem-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	>=kde-frameworks/plasma-${KFMIN}:5
-	>=kde-frameworks/prison-${KFMIN}:5[qml]
-	>=kde-frameworks/solid-${KFMIN}:5
-	>=kde-plasma/breeze-${PVCUT}:5
-	>=kde-plasma/kscreenlocker-${PVCUT}:5
-	>=kde-plasma/kwin-${PVCUT}:5
-	>=kde-plasma/libkscreen-${PVCUT}:5
-	>=kde-plasma/libksysguard-${PVCUT}:5
-	>=kde-plasma/libkworkspace-${PVCUT}:5
-	>=media-libs/phonon-4.11.0
-	sys-libs/zlib
-	x11-libs/libICE
-	x11-libs/libSM
-	x11-libs/libX11
-	x11-libs/libXau
-	x11-libs/libxcb
-	x11-libs/libXcursor
-	x11-libs/libXfixes
-	x11-libs/libXrender
-	x11-libs/libXtst
-	x11-libs/xcb-util
-	x11-libs/xcb-util-image
-	appstream? ( dev-libs/appstream[qt5] )
-	calendar? ( >=kde-frameworks/kholidays-${KFMIN}:5 )
-	fontconfig? (
-		media-libs/fontconfig
-		media-libs/freetype
-		x11-libs/libXft
-		x11-libs/xcb-util-image
-	)
-	geolocation? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
-	gps? ( sci-geosciences/gpsd )
-	qalculate? ( sci-libs/libqalculate:= )
-	screencast? (
-		>=media-video/pipewire-0.3:=
-		x11-libs/libdrm
-	)
-	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
-	telemetry? ( dev-libs/kuserfeedback:5 )
-"
-DEPEND="${COMMON_DEPEND}
-	>=dev-libs/plasma-wayland-protocols-1.1.1
-	>=dev-qt/qtconcurrent-${QTMIN}:5
-	x11-base/xorg-proto
-	fontconfig? ( x11-libs/libXrender )
-"
-RDEPEND="${COMMON_DEPEND}
-	app-text/iso-codes
-	>=dev-qt/qdbus-${QTMIN}:5
-	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
-	>=dev-qt/qtpaths-${QTMIN}:5
-	>=dev-qt/qtquickcontrols-${QTMIN}:5[widgets]
-	>=dev-qt/qtquickcontrols2-${QTMIN}:5
-	>=kde-apps/kio-extras-19.04.3:5
-	>=kde-frameworks/kdesu-${KFMIN}:5
-	>=kde-frameworks/kirigami-${KFMIN}:5
-	>=kde-frameworks/kquickcharts-${KFMIN}:5
-	>=kde-plasma/ksysguard-${PVCUT}:5
-	>=kde-plasma/milou-${PVCUT}:5
-	>=kde-plasma/plasma-integration-${PVCUT}:5
-	x11-apps/xmessage
-	x11-apps/xprop
-	x11-apps/xrdb
-	x11-apps/xsetroot
-	systemd? ( sys-apps/dbus[user-session] )
-	!systemd? ( sys-apps/dbus )
-	!<kde-plasma/plasma-desktop-5.19.80:5
-"
-PDEPEND="
-	>=kde-plasma/kde-cli-tools-${PVCUT}:5
-"
-
-PATCHES=( "${FILESDIR}/${PN}-5.14.2-split-libkworkspace.patch" )
-
-src_prepare() {
-	ecm_src_prepare
-
-	cmake_comment_add_subdirectory libkworkspace
-	# delete colliding libkworkspace translations
-	if [[ ${KDE_BUILD_TYPE} = release ]]; then
-		find po -type f -name "*po" -and -name "libkworkspace*" -delete || die
-	fi
-
-	# TODO: try to get a build switch upstreamed
-	if ! use screencast; then
-		sed -e "s/^pkg_check_modules.*PipeWire/#&/" \
-			-i CMakeLists.txt || die
-	fi
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_xembed-sni-proxy=OFF
-		$(cmake_use_find_package appstream AppStreamQt)
-		$(cmake_use_find_package calendar KF5Holidays)
-		$(cmake_use_find_package fontconfig Fontconfig)
-		$(cmake_use_find_package geolocation KF5NetworkManagerQt)
-		$(cmake_use_find_package qalculate Qalculate)
-		$(cmake_use_find_package semantic-desktop KF5Baloo)
-		$(cmake_use_find_package telemetry KUserFeedback)
-	)
-
-	use geolocation && mycmakeargs+=( $(cmake_use_find_package gps libgps) )
-
-	ecm_src_configure
-}
-
-src_install() {
-	ecm_src_install
-
-	# default startup and shutdown scripts
-	insinto /etc/xdg/plasma-workspace/env
-	doins "${FILESDIR}"/10-agent-startup.sh
-
-	insinto /etc/xdg/plasma-workspace/shutdown
-	doins "${FILESDIR}"/10-agent-shutdown.sh
-	fperms +x /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh
-}
-
-pkg_postinst () {
-	ecm_pkg_postinst
-
-	# Clean up pre-5.17.4 dirs
-	rmdir -v "${EROOT}"/etc/plasma{/startup,/shutdown,} 2> /dev/null
-
-	elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
-	elog "edit ${EPREFIX}/etc/xdg/plasma-workspace/env/10-agent-startup.sh"
-	elog "and ${EPREFIX}/etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
-}