media-libs/avidemux-core: 2.7.0 version bump

Add x11-libs/libva slot operator.

Closes: https://bugs.gentoo.org/641636
Package-Manager: Portage-2.3.19, Repoman-2.3.6

3 files changed, 101 insertions, 2 deletions

diff --git a/media-libs/avidemux-core/Manifest b/media-libs/avidemux-core/Manifest
index ae61dc9d9074..c86d53e23df3 100644
--- a/media-libs/avidemux-core/Manifest
+++ b/media-libs/avidemux-core/Manifest
@@ -1 +1,2 @@
 DIST avidemux_2.6.20.tar.gz 20172362 BLAKE2B d458749e470e60b133a177ddf97ee04a665da3f7b2c52e8cc51f907aa5b51d11338ddab9306603b615170b5cf75ec2d3444bd648756bdb724aa442abf7044553 SHA512 d01d0fc24a3004770bd3923c2debc4fa2752eb71df08cfe423746b9c44a2562ca01d82965ed2563b99572a4bed8034b79487199ce330208b51a3b7f87ccf7103
+DIST avidemux_2.7.0.tar.gz 21474504 BLAKE2B c6e55a0b5220d6d3746fa06162bf11253145fd28f2f6f744702d5e0342fba85e546a28883eb847139eadd34c94037ebc7d68f5576e7505a85288556468d14b96 SHA512 7c92213d3bd2849dbdb5a1aff2acd6da231fd76c561b756fbf4a1d5a41e9705d609d7a35b6ca6b77ceb3bf5138f861cd24ed16d8fcec4fd713f09a2ff07e9015
diff --git a/media-libs/avidemux-core/avidemux-core-2.7.0.ebuild b/media-libs/avidemux-core/avidemux-core-2.7.0.ebuild
new file mode 100644
index 000000000000..92f9f8ec0689
--- /dev/null
+++ b/media-libs/avidemux-core/avidemux-core-2.7.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/mean00/avidemux2.git"
+	EGIT_CHECKOUT_DIR=${WORKDIR}
+	inherit git-r3
+else
+	MY_PN="${PN/-core/}"
+	MY_P="${MY_PN}_${PV}"
+	SRC_URI="mirror://sourceforge/${MY_PN}/${MY_PN}/${PV}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+inherit cmake-utils
+
+DESCRIPTION="Core libraries for simple video cutting, filtering and encoding tasks"
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+
+# Multiple licenses because of all the bundled stuff.
+LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
+SLOT="2.7"
+IUSE="debug nls nvenc sdl system-ffmpeg vaapi vdpau xv"
+
+# Trying to use virtual; ffmpeg misses aac,cpudetection USE flags now though, are they needed?
+COMMON_DEPEND="
+	dev-db/sqlite:3
+	nvenc? ( media-video/nvidia_video_sdk )
+	sdl? ( media-libs/libsdl:0 )
+	system-ffmpeg? ( >=virtual/ffmpeg-9:0[mp3,theora] )
+	vaapi? ( x11-libs/libva:0= )
+	vdpau? ( x11-libs/libvdpau:0 )
+	xv? ( x11-libs/libXv:0 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<media-video/avidemux-${PV}:${SLOT}
+	nls? ( virtual/libintl:0 )
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	!system-ffmpeg? ( dev-lang/yasm[nls=] )
+"
+
+S="${WORKDIR}/${MY_P}"
+CMAKE_USE_DIR="${S}/${PN/-/_}"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if use system-ffmpeg ; then
+		# Preparations to support the system ffmpeg. Currently fails because
+		# it depends on files the system ffmpeg doesn't install.
+		local error="Failed to remove bundled ffmpeg."
+
+		rm -r cmake/admFFmpeg* cmake/ffmpeg* avidemux_core/ffmpeg_package \
+			buildCore/ffmpeg || die "${error}"
+		sed -e 's/include(admFFmpegUtil)//g' -e '/registerFFmpeg/d' \
+			-i avidemux/commonCmakeApplication.cmake || die "${error}"
+		sed -e 's/include(admFFmpegBuild)//g' \
+			-i avidemux_core/CMakeLists.txt || die "${error}"
+	fi
+}
+
+src_configure() {
+	# Add lax vector typing for PowerPC.
+	if use ppc || use ppc64 ; then
+		append-cflags -flax-vector-conversions
+	fi
+
+	# See bug 432322.
+	use x86 && replace-flags -O0 -O1
+
+	local mycmakeargs=(
+		-DAVIDEMUX_SOURCE_DIR='${S}'
+		-DGETTEXT="$(usex nls)"
+		-DNVENC="$(usex nvenc)"
+		-DSDL="$(usex sdl)"
+		-DLIBVA="$(usex vaapi)"
+		-DVDPAU="$(usex vdpau)"
+		-DXVIDEO="$(usex xv)"
+	)
+
+	if use debug ; then
+		mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile -j1
+}
+
+src_install() {
+	cmake-utils_src_install -j1
+}
diff --git a/media-libs/avidemux-core/avidemux-core-9999.ebuild b/media-libs/avidemux-core/avidemux-core-9999.ebuild
index b99cdefa4506..92f9f8ec0689 100644
--- a/media-libs/avidemux-core/avidemux-core-9999.ebuild
+++ b/media-libs/avidemux-core/avidemux-core-9999.ebuild
@@ -20,7 +20,7 @@ HOMEPAGE="http://fixounet.free.fr/avidemux"
 
 # Multiple licenses because of all the bundled stuff.
 LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
-SLOT="2.6"
+SLOT="2.7"
 IUSE="debug nls nvenc sdl system-ffmpeg vaapi vdpau xv"
 
 # Trying to use virtual; ffmpeg misses aac,cpudetection USE flags now though, are they needed?
@@ -29,7 +29,7 @@ COMMON_DEPEND="
 	nvenc? ( media-video/nvidia_video_sdk )
 	sdl? ( media-libs/libsdl:0 )
 	system-ffmpeg? ( >=virtual/ffmpeg-9:0[mp3,theora] )
-	vaapi? ( x11-libs/libva:0 )
+	vaapi? ( x11-libs/libva:0= )
 	vdpau? ( x11-libs/libvdpau:0 )
 	xv? ( x11-libs/libXv:0 )
 "