media-libs/libmediainfo: version bump to 19.09

Signed-off-by: Tim Harder <radhermit@gentoo.org>

2 files changed, 84 insertions, 0 deletions

diff --git a/media-libs/libmediainfo/Manifest b/media-libs/libmediainfo/Manifest
index 5fd597e5b793..8883eea8aab6 100644
--- a/media-libs/libmediainfo/Manifest
+++ b/media-libs/libmediainfo/Manifest
@@ -1 +1,2 @@
 DIST libmediainfo_19.07.tar.xz 1685616 BLAKE2B 15f2663557735f50537fbf69d974cd6a21af337540c87de67f03276eb14f14ab72bd235d9f289bb6431792d08a8c7b7063ae37453c83ea043376fa6a4a370d73 SHA512 b16a161be548ae86e5e1fe54f86614f6f3b151b86afb657cf0ea96aa0278b0158309e0382dac0dd0ada5e5af7a2f58369e6fa97bfc7306a3bbc82792c0a29ecc
+DIST libmediainfo_19.09.tar.xz 1764640 BLAKE2B aa1a93cbbdf17e2b1eb20efed4909c5d86e897796e1e184f1bb5eed50e1eb154f426b420551e25cb220f66059618b6f719c47333b816258eea6e3c30304892b2 SHA512 7f3afbb1c2df6e2dec44485a4eda8609d6b95c1b8e41354cef6b94549f77a506e237c7d43f5472aadf1c0ef2bd88dc24ba0eb493a763ba51871bb287233ae779
diff --git a/media-libs/libmediainfo/libmediainfo-19.09.ebuild b/media-libs/libmediainfo/libmediainfo-19.09.ebuild
new file mode 100644
index 000000000000..66497326e1f1
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-19.09.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic
+
+MY_PN="MediaInfo"
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="https://mediaarea.net/mediainfo/ https://github.com/MediaArea/MediaInfoLib"
+SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl doc mms static-libs"
+
+RDEPEND="sys-libs/zlib
+	dev-libs/tinyxml2:=
+	>=media-libs/libzen-0.4.37[static-libs=]
+	curl? ( net-misc/curl )
+	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+# tests try to fetch data from online sources
+RESTRICT="test"
+
+S=${WORKDIR}/${MY_PN}Lib/Project/GNU/Library
+
+src_prepare() {
+	eapply -p4 "${FILESDIR}"/${PN}-0.7.63-pkgconfig.patch
+	eapply_user
+
+	sed -i 's:-O2::' configure.ac || die
+	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		--with-libtinyxml2 \
+		$(use_with curl libcurl) \
+		$(use_with mms libmms) \
+		$(use_enable static-libs static) \
+		$(use_enable static-libs staticlibs)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${WORKDIR}"/${MY_PN}Lib/Doc/*.html )
+	fi
+
+	default
+
+	edos2unix ${PN}.pc #414545
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	insinto /usr/include/${MY_PN}DLL
+	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+
+	find "${ED}" -name '*.la' -delete || die
+}