media-sound/linuxsampler: bump to 2.2.0

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

1 files changed, 77 insertions, 0 deletions

diff --git a/media-sound/linuxsampler/linuxsampler-2.2.0.ebuild b/media-sound/linuxsampler/linuxsampler-2.2.0.ebuild
new file mode 100644
index 000000000000..db469f65a3ab
--- /dev/null
+++ b/media-sound/linuxsampler/linuxsampler-2.2.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="Software audio sampler engine with professional grade features"
+HOMEPAGE="https://www.linuxsampler.org/"
+SRC_URI="https://download.linuxsampler.org/packages/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa doc jack lv2 sf2 sqlite"
+REQUIRED_USE="|| ( alsa jack )"
+
+RDEPEND="
+	media-libs/libgig
+	media-libs/libsndfile[-minimal]
+	alsa? ( media-libs/alsa-lib )
+	jack? ( virtual/jack )
+	lv2? ( media-libs/lv2 )
+	sqlite? ( dev-db/sqlite )
+"
+DEPEND="${RDEPEND}
+	media-libs/dssi
+	media-libs/ladspa-sdk
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.0.0-nptl-hardened.patch"
+	"${FILESDIR}/${PN}-2.0.0-lv2-automagic.patch"
+	"${FILESDIR}/${PN}-2.1.1-fix-yyterror-not-declared.patch"
+)
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	default
+	# Force regeneration of the file to let it build with all bison
+	# versions, bug #556204
+	rm src/network/lscpparser.cpp || die
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-arts-driver
+		--disable-static
+		$(use_enable alsa alsa-driver)
+		$(use_enable jack jack-driver)
+		$(use_enable lv2)
+		$(use_enable sqlite instruments-db)
+		$(use_enable sf2 sf2-engine)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake
+	use doc && emake docs
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( doc/html/. )
+	default
+	find "${D}" -name '*.la' -delete || die
+
+	# lscp files conflict with nilfs-utils, bug #556330
+	mv "${D}/usr/bin/lscp" "${D}/usr/bin/lscp-${PN}" || die
+	mv "${D}/usr/share/man/man1/lscp.1" "${D}/usr/share/man/man1/lscp-${PN}.1" || die
+}