media-sound/linuxsampler: bump to 2.3.0 + eapi8

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 80 insertions, 2 deletions

diff --git a/media-sound/linuxsampler/Manifest b/media-sound/linuxsampler/Manifest
index f06007d683cb..22696ec5d51f 100644
--- a/media-sound/linuxsampler/Manifest
+++ b/media-sound/linuxsampler/Manifest
@@ -1 +1,2 @@
 DIST linuxsampler-2.2.0.tar.bz2 1507276 BLAKE2B 9650938d0aace876e817884121b824713dd2f747505344d7895e7d99da62f2214fb4c4bf43c398f4e486202e23e7a57288e19734e8c565a917d823169deb717a SHA512 9015bb8d3af125e13c5c2ef3ae2d3987f7b7dda72e238cff25e622a3291019f5e392195dd27e7e783c70d877d9b267915fc443369eb17117e5eb7c54b8496c68
+DIST linuxsampler-2.3.0.tar.bz2 1267738 BLAKE2B 5f9e7bf2f6c0bfe8131cc04d79b3df5c08c16c7332315e5ff39c16aa3565f88bc3a58b63db4162c8e2f4430ae1a091c928cecba2385fc181f6c7b46a72c4ae88 SHA512 5a59e3443ee6d3056fc274386ae222e7db72a8c6e316a1c39c5d631bae86ec6a61745b20e594cf569c10f5a6bd6eb0d09b3956cce67072175ff60a770a4b7e5b
diff --git a/media-sound/linuxsampler/linuxsampler-2.3.0.ebuild b/media-sound/linuxsampler/linuxsampler-2.3.0.ebuild
new file mode 100644
index 000000000000..834afefd18ce
--- /dev/null
+++ b/media-sound/linuxsampler/linuxsampler-2.3.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Software audio sampler engine with professional grade features"
+HOMEPAGE="https://www.linuxsampler.org/"
+SRC_URI="https://download.linuxsampler.org/packages/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa doc jack lv2 sf2 sqlite"
+REQUIRED_USE="|| ( alsa jack )"
+
+RDEPEND="
+	media-libs/libgig
+	media-libs/libsndfile[-minimal]
+	alsa? ( media-libs/alsa-lib )
+	jack? ( virtual/jack )
+	lv2? ( media-libs/lv2 )
+	sqlite? ( dev-db/sqlite )
+"
+DEPEND="${RDEPEND}
+	media-libs/dssi
+	media-libs/ladspa-sdk
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.0.0-nptl-hardened.patch"
+	"${FILESDIR}/${PN}-2.0.0-lv2-automagic.patch"
+	"${FILESDIR}/${PN}-2.1.1-fix-yyterror-not-declared.patch"
+)
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	default
+	# Force regeneration of the file to let it build with all bison
+	# versions, bug #556204
+	rm src/network/lscpparser.cpp || die
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-arts-driver
+		--disable-static
+		$(use_enable alsa alsa-driver)
+		$(use_enable jack jack-driver)
+		$(use_enable lv2)
+		$(use_enable sqlite instruments-db)
+		$(use_enable sf2 sf2-engine)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	# bug #666738
+	emake -j1
+	use doc && emake docs
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( doc/html/. )
+	default
+	find "${D}" -name '*.la' -delete || die
+
+	# lscp files conflict with nilfs-utils, bug #556330
+	mv "${D}/usr/bin/lscp" "${D}/usr/bin/lscp-${PN}" || die
+	mv "${D}/usr/share/man/man1/lscp.1" "${D}/usr/share/man/man1/lscp-${PN}.1" || die
+}
diff --git a/media-sound/linuxsampler/linuxsampler-9999.ebuild b/media-sound/linuxsampler/linuxsampler-9999.ebuild
index 423bbdb01686..abca02a402df 100644
--- a/media-sound/linuxsampler/linuxsampler-9999.ebuild
+++ b/media-sound/linuxsampler/linuxsampler-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit autotools subversion
 
@@ -11,7 +11,6 @@ ESVN_REPO_URI="https://svn.linuxsampler.org/svn/linuxsampler/trunk"
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS=""
 IUSE="alsa doc jack lv2 sf2 sqlite"
 REQUIRED_USE="|| ( alsa jack )"