media-video/pitivi: Fix RDEPEND (#588394 by poncho)

Package-Manager: portage-2.3.0

2 files changed, 78 insertions, 0 deletions

diff --git a/media-video/pitivi/Manifest b/media-video/pitivi/Manifest
index 029beb31a222..417622182981 100644
--- a/media-video/pitivi/Manifest
+++ b/media-video/pitivi/Manifest
@@ -1 +1,2 @@
 DIST pitivi-0.95.tar.xz 3341488 SHA256 5f15220bcc3d02cef4edacaa19da284014caf725e41fc9cbec70469582e1d313 SHA512 e628302ecbb790e955459a4dc124e8580081f6eff8abde210a1b537ae18696c3861bd619efe1434e8e1cf1069adb72cbff0cf44c64706c4046d2cfb7f9aecdfa WHIRLPOOL df6e625dddcf113a8e84aabf5a7a40d90e6b38130e63201a1674f4a576a735696c6b9a9a35b2743cbe5bac8d444c04cd0ea9c5a43358718e1b32b6ebc97f435c
+DIST pitivi-0.96.tar.xz 3324396 SHA256 fa0b469bb71ea10138144ec2adbe3e575d33678b5e48fc906e5e8cb8eb19ad84 SHA512 dd608effc1f7196ac4784d707ec5a6f25088a3a216262a004ed81fd4e078bc80dde67c0601cc690b4b6a3a8febeef6bd841c30513449cbf722aa23d5d655f00d WHIRLPOOL 4a61842cbd7704e2c2445fb47ce8016fc96be543b72825d092bfbcf6d35fdd3944d5395a09386c6102ffb1fc672a1c8226f7c48390cce43bcb23563b3fce6478
diff --git a/media-video/pitivi/pitivi-0.96-r1.ebuild b/media-video/pitivi/pitivi-0.96-r1.ebuild
new file mode 100644
index 000000000000..e1b6e7b6dc6b
--- /dev/null
+++ b/media-video/pitivi/pitivi-0.96-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{3_3,3_4,3_5} )
+PYTHON_REQ_USE="sqlite"
+
+inherit gnome2 python-single-r1 virtualx
+
+DESCRIPTION="A non-linear video editor using the GStreamer multimedia framework"
+HOMEPAGE="http://www.pitivi.org"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="v4l test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Do not forget to check pitivi/check.py for dependencies!!!
+# pycanberra, gnome-desktop, libav and libnotify are optional
+GST_VER="1.8.2"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/pycairo-1.10[${PYTHON_USEDEP}]
+	>=x11-libs/cairo-1.10
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-libs/glib-2.30.0:2
+
+	>=dev-libs/gobject-introspection-1.34:=
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	>=dev-python/gst-python-1.4:1.0[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pycanberra[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-3.8:3[${PYTHON_USEDEP}]
+	dev-python/pyxdg[${PYTHON_USEDEP}]
+
+	gnome-base/librsvg:=
+	gnome-base/gnome-desktop:3=[introspection]
+
+	>=media-libs/gstreamer-${GST_VER}:1.0[introspection]
+	>=media-libs/gstreamer-editing-services-${GST_VER}:1.0[introspection]
+	>=media-libs/gst-plugins-base-${GST_VER}:1.0
+	>=media-libs/gst-plugins-bad-${GST_VER}:1.0[gtk]
+	>=media-libs/gst-plugins-good-${GST_VER}:1.0
+	>=media-plugins/gst-plugins-libav-${GST_VER}:1.0
+	>=media-plugins/gst-transcoder-1.8
+
+	x11-libs/libnotify[introspection]
+	>=x11-libs/gtk+-3.20.0:3[introspection]
+
+	v4l? ( >=media-plugins/gst-plugins-v4l2-${GST_VER}:1.0 )
+"
+DEPEND="${RDEPEND}
+	app-text/yelp-tools
+	dev-python/setuptools
+	>=dev-util/intltool-0.35.5
+	dev-util/itstool
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( dev-python/mock[${PYTHON_USEDEP}] )
+"
+
+src_test() {
+	export PITIVI_TOP_LEVEL_DIR="${S}"
+	virtx emake check
+}
+
+src_install() {
+	gnome2_src_install
+	python_fix_shebang "${D}"
+}