media-video/rtmpdump: fix librtmp pkg-config paths for Prefix.

  Bump -9999 to EAPI 6 and git-r3 as a side effect.

Bug: 616202

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 81 insertions, 0 deletions

diff --git a/media-video/rtmpdump/rtmpdump-2.4_p20161210-r1.ebuild b/media-video/rtmpdump/rtmpdump-2.4_p20161210-r1.ebuild
new file mode 100644
index 000000000000..13ae3a45a589
--- /dev/null
+++ b/media-video/rtmpdump/rtmpdump-2.4_p20161210-r1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit multilib toolchain-funcs multilib-minimal flag-o-matic
+
+DESCRIPTION="RTMP client intended to stream audio or video flash content"
+HOMEPAGE="http://rtmpdump.mplayerhq.hu/"
+SRC_URI="https://dev.gentoo.org/~hwoarang/distfiles/${P}.tar.gz"
+
+# the library is LGPL-2.1, the command is GPL-2
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="gnutls polarssl ssl libressl"
+
+DEPEND="ssl? (
+		gnutls? ( >=net-libs/gnutls-2.12.23-r6[${MULTILIB_USEDEP},nettle(+)] )
+		polarssl? ( !gnutls? ( >=net-libs/polarssl-1.3.4[${MULTILIB_USEDEP}] ) )
+		!gnutls? ( !polarssl? ( !libressl? ( >=dev-libs/openssl-1.0.1h-r2[${MULTILIB_USEDEP}] ) libressl? ( dev-libs/libressl ) ) )
+		>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	)"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	if ! use ssl && { use gnutls || use polarssl; }; then
+		ewarn "USE='gnutls polarssl' are ignored without USE='ssl'."
+		ewarn "Please review the local USE flags for this package."
+	fi
+}
+
+src_unpack() {
+	mkdir -p "${S}" || die "Can't create source directory"
+	cd "${S}" || die
+	unpack ${A}
+}
+
+src_prepare() {
+	# fix #571106 by restoring pre-GCC5 inline semantics
+	append-cflags -std=gnu89
+	# fix Makefile ( bug #298535 , bug #318353 and bug #324513 )
+	sed -i 's/\$(MAKEFLAGS)//g' Makefile \
+		|| die "failed to fix Makefile"
+	sed -i -e 's:OPT=:&-fPIC :' \
+		-e 's:OPT:OPTS:' \
+		-e 's:CFLAGS=.*:& $(OPT):' librtmp/Makefile \
+		|| die "failed to fix Makefile"
+	eapply_user
+	multilib_copy_sources
+}
+
+multilib_src_compile() {
+	if use ssl ; then
+		if use gnutls ;	then
+			crypto="GNUTLS"
+		elif use polarssl ; then
+			crypto="POLARSSL"
+		else
+			crypto="OPENSSL"
+		fi
+	fi
+	#fix multilib-script support. Bug #327449
+	sed -i "/^libdir/s:lib$:$(get_libdir):" librtmp/Makefile || die
+	if ! multilib_is_native_abi; then
+		cd librtmp || die
+	fi
+	emake CC="$(tc-getCC)" LD="$(tc-getLD)" \
+		OPT="${CFLAGS}" XLDFLAGS="${LDFLAGS}" CRYPTO="${crypto}" SYS=posix
+}
+
+multilib_src_install() {
+	mkdir -p "${ED}"/usr/$(get_libdir) || die
+	if multilib_is_native_abi; then
+		dodoc README ChangeLog rtmpdump.1.html rtmpgw.8.html
+	else
+		cd librtmp || die
+	fi
+	emake DESTDIR="${D}" prefix="${EPREFIX}/usr" mandir='$(prefix)/share/man' \
+		CRYPTO="${crypto}" install
+}