net-ftp/pureadmin: Port to EAPI 7

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: David Seifert <soap@gentoo.org>

2 files changed, 32 insertions, 25 deletions

diff --git a/net-ftp/pureadmin/files/pureadmin-0.4-QA-desktop-file.patch b/net-ftp/pureadmin/files/pureadmin-0.4-QA-desktop-file.patch
new file mode 100644
index 000000000000..39b47f60115b
--- /dev/null
+++ b/net-ftp/pureadmin/files/pureadmin-0.4-QA-desktop-file.patch
@@ -0,0 +1,9 @@
+--- a/pureadmin.desktop.in
++++ b/pureadmin.desktop.in
+@@ -9,5 +9,5 @@
+ StartupNotify=true
+ Terminal=false
+ Type=Application
+-Categories=GTK;Application;System;
++Categories=GTK;System;
+ 
diff --git a/net-ftp/pureadmin/pureadmin-0.4-r1.ebuild b/net-ftp/pureadmin/pureadmin-0.4-r1.ebuild
index 815d949ac40e..e2cb7b43a5f8 100644
--- a/net-ftp/pureadmin/pureadmin-0.4-r1.ebuild
+++ b/net-ftp/pureadmin/pureadmin-0.4-r1.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=4
+EAPI=7
 
-inherit eutils
+inherit desktop
 
 DESCRIPTION="GUI tool used to make the management of Pure-FTPd a little easier"
 HOMEPAGE="http://purify.sourceforge.net/"
@@ -12,41 +12,38 @@ SRC_URI="mirror://sourceforge/purify/${P}.tar.gz"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="amd64 ~ppc x86"
-IUSE="debug doc"
+IUSE="doc"
 
 RDEPEND="
 	gnome-base/libglade:2.0
 	sys-libs/zlib
 	virtual/fam
 	x11-libs/gtk+:2"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
 
-src_prepare() {
-	cat >> po/POTFILES.skip <<- EOF
-	src/eggstatusicon.c
-	src/eggtrayicon.c
-	src/prereq_usrmanager.c
-	EOF
-	epatch "${FILESDIR}"/${P}-gold.patch
-}
-
-src_configure() {
-	local myconf=""
+PATCHES=(
+	"${FILESDIR}"/${P}-gold.patch
+	"${FILESDIR}"/${P}-QA-desktop-file.patch
+)
 
-	use debug && myconf="${myconf} --enable-debug"
+src_prepare() {
+	default
 
-	econf ${myconf}
+	cat >> po/POTFILES.skip <<- EOF || die
+		src/eggstatusicon.c
+		src/eggtrayicon.c
+		src/prereq_usrmanager.c
+	EOF
 }
 
 src_install() {
 	default
 
 	# Move the docs to the correct location, if we want the docs
-	if use doc ; then
-		dodoc "${ED}"usr/share/pureadmin/docs/*
-	fi
-	rm -Rfv "${ED}"usr/share/pureadmin/docs || die
+	use doc &&
+		dodoc -r "${ED}"/usr/share/pureadmin/docs/.
+	rm -Rfv "${ED}"/usr/share/pureadmin/docs || die
 
 	make_desktop_entry pureadmin "Pure-FTPd menu config" pureadmin
 }
@@ -55,8 +52,9 @@ pkg_postinst() {
 	ewarn "PureAdmin is at a beta-stage right now and it may break your"
 	ewarn "configuration. DO NOT use it for safety critical system"
 	ewarn "or production use!"
-	echo
+
+	elog
 	elog "You need root-privileges to be able to use PureAdmin."
 	elog "This will probably change in the future."
-	echo
+	elog
 }