proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 65 insertions, 0 deletions

diff --git a/net-libs/aqbanking/aqbanking-5.5.1.ebuild b/net-libs/aqbanking/aqbanking-5.5.1.ebuild
new file mode 100644
index 000000000000..3583b874269f
--- /dev/null
+++ b/net-libs/aqbanking/aqbanking-5.5.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils
+
+MY_P="${P/_beta/beta}"
+DESCRIPTION="Generic Online Banking Interface"
+HOMEPAGE="http://www.aquamaniac.de/aqbanking/"
+SRC_URI="http://www.aquamaniac.de/sites/download/download.php?package=03&release=118&file=01&dummy=${MY_P}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="chipcard debug doc ebics examples gtk ofx"
+
+RDEPEND=">=app-misc/ktoblzcheck-1.48
+	>=dev-libs/gmp-5
+	>=sys-libs/gwenhywfar-4.13.1[gtk?]
+	virtual/libintl
+	ofx? ( >=dev-libs/libofx-0.9.5 )
+	chipcard? ( >=sys-libs/libchipcard-5.0.2 )
+	ebics? ( dev-libs/xmlsec[gcrypt,gnutls] )"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+MAKEOPTS="${MAKEOPTS} -j1" # 5.0.x fails with -j9 on quadcore
+
+src_configure() {
+	local backends="aqhbci aqnone aqpaypal"
+	use ofx && backends="${backends} aqofxconnect"
+	use ebics && backends="${backends} aqebics"
+
+	local mytest
+	use gtk && mytest="--enable-gui-tests"
+
+	econf \
+		$(use_enable debug) \
+		$(use_enable doc full-doc) \
+		--with-backends="${backends}" \
+		--with-docpath=/usr/share/doc/${PF}/apidoc \
+		${mytest}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	rm -rf "${ED}"/usr/share/doc/aq{banking,hbci,paypal}
+
+	dodoc AUTHORS ChangeLog NEWS README TODO
+
+	newdoc src/plugins/backends/aqhbci/tools/aqhbci-tool/README \
+		README.aqhbci-tool
+
+	if use examples; then
+		docinto tutorials
+		dodoc tutorials/*.{c,h} tutorials/README
+	fi
+
+	prune_libtool_files --all
+}