net-voip/telepathy-gabble: bump to 0.18.4, EAPI-6; remove unused twisted deps, eutils.eclass

2 files changed, 81 insertions, 0 deletions

diff --git a/net-voip/telepathy-gabble/Manifest b/net-voip/telepathy-gabble/Manifest
index 0a8bc3bbcf54..147b4bd1a806 100644
--- a/net-voip/telepathy-gabble/Manifest
+++ b/net-voip/telepathy-gabble/Manifest
@@ -1 +1,2 @@
 DIST telepathy-gabble-0.18.3.tar.gz 2793195 SHA256 8ec714607e9bcb8d5a3f44adf871e7b07d5db8e326e47536e74e09cba59989c2 SHA512 51c7b754779d131c54facf8e373338bd471e6bb589d69cd8f9c0f4450b15d9676c2bbf762b64e9c3bf7067bca0e9accb6c766f2fda0051a26a36eb009d7bd5eb WHIRLPOOL e1e1e11e8a64c4587e74188827ad62ca702f7058d7d781fa7b982514bf5c16f24bb7711d38a36c113738303e9c0a90727cf57761818c55360ebf13c737d3f2c2
+DIST telepathy-gabble-0.18.4.tar.gz 2584311 SHA256 115c91572c72d4a40f0b25b606167b4f2f09441dc7bf1036ccbb1450f1a4969c SHA512 4303f1da7eeadf1f0e69fa881cd8b08dc41f4fd061df3f2ecdc80735d8be3e8cf24d8482f265f1858d8dfed71f62e8bc02c13f9525db8d21c9d927e25fa66218 WHIRLPOOL 882b2aee87abdcf6e404e4a42bb3e3c8d4e8ecc1263deb38c2479455b3a08b58d70ddfb421c6942fb2551dde0a3fcf21e799ad6db6df22a5c0dcfc9fc7ec8d03
diff --git a/net-voip/telepathy-gabble/telepathy-gabble-0.18.4.ebuild b/net-voip/telepathy-gabble/telepathy-gabble-0.18.4.ebuild
new file mode 100644
index 000000000000..fc0fa830f512
--- /dev/null
+++ b/net-voip/telepathy-gabble/telepathy-gabble-0.18.4.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+# Python is used during build for some scripted source files generation (and twisted tests)
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1
+
+DESCRIPTION="A XMPP connection manager, handles single and multi user chats and voice calls"
+HOMEPAGE="https://telepathy.freedesktop.org/"
+SRC_URI="https://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
+IUSE="gnutls +jingle plugins test"
+
+# Prevent false positives due nested configure
+QA_CONFIGURE_OPTIONS=".*"
+
+# FIXME: missing sasl-2 for tests ? (automagic)
+# missing libiphb for wocky ?
+# x11-libs/gtksourceview:3.0 needed by telepathy-gabble-xmpp-console, bug #495184
+# Keep in mind some deps or higher minimum versions are in ext/wocky/configure.ac
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=sys-apps/dbus-1.1.0
+	>=dev-libs/dbus-glib-0.82
+	>=net-libs/telepathy-glib-0.19.9
+
+	dev-libs/libxml2
+	dev-db/sqlite:3
+
+	gnutls? ( >=net-libs/gnutls-2.10.2 )
+	!gnutls? ( >=dev-libs/openssl-0.9.8g:0[-bindist] )
+	jingle? (
+		>=net-libs/libsoup-2.42
+		>=net-libs/libnice-0.0.11 )
+	plugins? ( x11-libs/gtksourceview:3.0[introspection] )
+
+	!<net-im/telepathy-mission-control-5.5.0
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	>=dev-util/gtk-doc-am-1.17
+	dev-libs/libxslt"
+# Twisted tests fail if bad ipv6 setup, upstream bug #30565
+# Random twisted tests fail with org.freedesktop.DBus.Error.NoReply for some reason
+# pygobject:2 is needed by twisted-17 for gtk2reactor usage by gabble
+#test? (
+#	dev-python/pygobject:2
+#	|| (
+#	>=dev-python/twisted-16.0.0
+#	(	>=dev-python/twisted-core-0.8.2
+#		>=dev-python/twisted-words-0.8.2
+#		>=dev-python/dbus-python-0.83
+#	) )
+#)
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-coding-style-checks \
+		--disable-static \
+		--disable-Werror \
+		--enable-file-transfer \
+		$(use_enable jingle voip) \
+		$(use_enable jingle google-relay) \
+		$(use_enable plugins) \
+		--with-tls=$(usex gnutls gnutls openssl)
+}
+
+src_test() {
+	# This runs only C tests (see tests/README):
+	emake -C tests check-TESTS
+}