proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 69 insertions, 0 deletions

diff --git a/sci-libs/ccpn-data/ccpn-data-2.3.1_p140425.ebuild b/sci-libs/ccpn-data/ccpn-data-2.3.1_p140425.ebuild
new file mode 100644
index 000000000000..4dc7b171156d
--- /dev/null
+++ b/sci-libs/ccpn-data/ccpn-data-2.3.1_p140425.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils portability python-r1 versionator
+
+PATCHSET="${PV##*_p}"
+MY_PN="${PN/-data}mr"
+MY_PV="$(replace_version_separator 3 _ ${PV%%_p*})r2"
+MY_MAJOR="$(get_version_component_range 1-3)"
+
+DESCRIPTION="The Collaborative Computing Project for NMR - Data"
+HOMEPAGE="http://www.ccpn.ac.uk/ccpn"
+SRC_URI="http://www2.ccpn.ac.uk/download/${MY_PN}/analysis${MY_PV}.tar.gz"
+[[ -n ${PATCHSET} ]] && SRC_URI+=" http://dev.gentoo.org/~jlec/distfiles/ccpn-update-${MY_MAJOR}-${PATCHSET}.patch.xz"
+
+SLOT="0"
+LICENSE="|| ( CCPN LGPL-2.1 )"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	!<sci-chemistry/ccpn-${PVR}"
+DEPEND=""
+
+RESTRICT="binchecks strip"
+
+S="${WORKDIR}"/ccpnmr/ccpnmr2.3
+
+src_prepare() {
+	[[ -n ${PATCHSET} ]] && \
+		epatch "${WORKDIR}"/ccpn-update-${MY_MAJOR}-${PATCHSET}.patch
+	cp "${FILESDIR}"/312+ccpn_rhf22_2013-10-02-16-17-30-923_00001.xml data/ccp/nmr/NmrExpPrototype/ || die
+}
+
+src_install() {
+	local i pydocs in_path ein_path
+
+	dodir /usr/share/doc/${PF}/html
+	sed \
+		-e "s:../ccpnmr2.1:${EPREFIX}/usr/share/doc/${PF}/html:g" \
+		../doc/index.html > "${ED}"/usr/share/doc/${PF}/html/index.html || die
+	treecopy $(find python/ -name doc -type d) "${ED}"/usr/share/doc/${PF}/html/
+
+	pydocs="$(find python -name doc -type d)"
+
+	symlinking() {
+		in_path=$(python_get_sitedir)/ccpn
+		ein_path="${in_path#${EPREFIX}}"
+		dosym ../../../../share/doc/${PF}/html ${ein_path}/doc
+		for i in ${pydocs}; do
+			dosym /usr/share/doc/${PF}/html/${i} ${ein_path}/${i}
+		done
+		dosym /usr/share/ccpn/data ${ein_path}/data
+		dosym /usr/share/ccpn/model ${ein_path}/model
+	}
+	python_foreach_impl symlinking
+
+	dohtml -r doc/*
+	insinto /usr/share/ccpn
+	doins -r data model
+}