sci-libs/cddlib: new version 094j.

François Bissey had an ebuild for the latest version of this package in
the sage-on-gentoo overlay, so I've imported it with minor changes:

  * Updated to EAPI=7 (no related changes).
  * Dropped the unused autotools.eclass inherit.
  * Changed GPL-2 to GPL-2+, since the files that do have copyright
    headers have the "or any later version" bit.
  * Dropped the DOCS declaration; they're all covered by einstalldocs.
  * Added IUSE=examples.
  * Reworked the documentation/example installation logic. The new
    autotools build system installs everything by default, so if
    the user doesn't want something, we have to kill it from $ED.

I've also added the upstream remote to metadata.xml, and added myself
and François as maintainers in the future.

SageMath uses two cddlib executables only present as of this version,
so it's a prerequisite for moving more of SageMath into the tree.

Closes: https://bugs.gentoo.org/705218
Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/sci-libs/cddlib/cddlib-094j.ebuild b/sci-libs/cddlib/cddlib-094j.ebuild
new file mode 100644
index 000000000000..73468ab72e6d
--- /dev/null
+++ b/sci-libs/cddlib/cddlib-094j.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# This should have been dealt with versionator in the direction
+# 0.94x -> 094x - now we are screwed.
+MY_PV="0.94j"
+MY_P="${PN}-${MY_PV}"
+DESCRIPTION="C library implementing the Double Description Method"
+HOMEPAGE="https://www.inf.ethz.ch/personal/fukudak/cdd_home/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${MY_PV}/${MY_P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2+"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples static-libs tools"
+
+DEPEND="dev-libs/gmp:0"
+RDEPEND="dev-libs/gmp:0="
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_install() {
+	default
+
+	if ! use tools; then
+		rm "${ED}"/usr/bin/* || die
+	fi
+
+	if ! use static-libs; then
+		find "${ED}" -name '*.la' -delete || die
+	fi
+
+	# Nobody wants the dvi/ps manual...
+	rm "${ED}/usr/share/doc/${PF}"/cddlibman.{dvi,ps} || die
+
+	# since the PDF manual is installed by default.
+	if ! use doc; then
+		rm "${ED}/usr/share/doc/${PF}"/cddlibman.pdf || die
+	fi
+
+	# The docs and examples are *both* installed by default, so we
+	# have to remove the examples if the user doesn't want them.
+	docompress -x "/usr/share/doc/${PF}"/examples{,-ext,-ine,-ine3d}
+	if ! use examples; then
+		rm -r "${ED}/usr/share/doc/${PF}"/examples{,-ext,-ine,-ine3d} || die
+	fi
+}