sci-libs/gerris: Patch use of sci-libs/lis function prototypes

Gentoo-bug: 593282
* EAPI=6
* Made all PATCHES -p1 compliant
* Exchanged -D_BSD_SOURCE with -D_DEFAULT_SOURCE in order
  to silence deprecation from dev-libs/glib
* Add subslot operators for sci-libs/netcdf and sci-libs/gsl
* Add proper SLOT and operator for sci-libs/fftw
* Delete all .la files, as package provides .pc files

Package-Manager: portage-2.3.0

1 files changed, 71 insertions, 0 deletions

diff --git a/sci-libs/gerris/gerris-20131206-r1.ebuild b/sci-libs/gerris/gerris-20131206-r1.ebuild
new file mode 100644
index 000000000000..464ca8ab0de8
--- /dev/null
+++ b/sci-libs/gerris/gerris-20131206-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools flag-o-matic toolchain-funcs
+
+MY_P=${P/-20/-snapshot-}
+
+DESCRIPTION="Gerris Flow Solver"
+HOMEPAGE="http://gfs.sourceforge.net/"
+SRC_URI="http://gerris.dalembert.upmc.fr/gerris/tarballs/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples mpi static-libs"
+
+# all these deps could be optional
+# but the configure.in would have to be modified
+# heavily for the automagic
+RDEPEND="
+	dev-libs/glib:2
+	dev-games/ode
+	sci-libs/netcdf:=
+	sci-libs/gsl:=
+	sci-libs/gts
+	sci-libs/hypre[mpi?]
+	sci-libs/lis[mpi?]
+	sci-libs/proj
+	sci-libs/fftw:3.0=
+	virtual/lapack
+	mpi? ( virtual/mpi )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+# buggy tests, need extra packages and require gerris to be installed
+RESTRICT=test
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20130531-hypre-no-mpi.patch
+	"${FILESDIR}"/${PN}-20130531-lis-matrix-csr.patch
+	"${FILESDIR}"/${PN}-20130531-use-blas-lapack-system.patch
+	"${FILESDIR}"/${PN}-20131206-lis-api-change.patch
+	"${FILESDIR}"/${PN}-20131206-DEFAULT_SOURCE-replacement.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	append-cppflags "-I${EPREFIX}/usr/include/hypre"
+	econf \
+		--enable-shared \
+		$(use_enable static-libs static) \
+		$(use_enable mpi) \
+		LAPACK_LIBS="$($(tc-getPKG_CONFIG) --libs lapack)"
+}
+
+src_install() {
+	default
+	use examples && dodoc -r doc/examples
+
+	find "${D}" -name '*.la' -delete || die
+}